Question

我正在努力学习如何正确使用FsCheck，并将其与Expecto集成。如果我使用默认的FsCheck配置，我可以运行属性测试，但是当我尝试使用自己的Generator时，它会导致堆栈溢出异常。

这是我的发电机

type NameGen() =
    static member Name() =
        Arb.generate<string * string>
        |> Gen.where (fun (firstName, lastName) ->
            firstName.Length > 0 && lastName.Length > 0
        )
        |> Gen.map (fun (first, last) -> sprintf "%s %s" first last)
        |> Arb.fromGen
        |> Arb.convert string id

我试图像这样使用它：

let config = { FsCheckConfig.defaultConfig with arbitrary = [typeof<NameGen>] }

let propertyTests input =
    let output = toInitials input
    output.EndsWith(".")

testPropertyWithConfig config "Must end with period" propertyTests

在进入Gen.where函数

之前抛出异常

我做错了什么？感谢

Answer 1

您正在尝试使用FsCheck的字符串生成器来重新定义其字符串生成器的工作方式，但是当您这样做时，它将递归调用自身，直到它耗尽堆栈空间。这是一个众所周知的问题：https://github.com/fscheck/FsCheck/issues/109

这种替代方案有用吗？

type NameGen =
    static member Name () =
        Arb.Default.NonEmptyString().Generator
        |> Gen.map (fun (NonEmptyString s) -> s)
        |> Gen.two
        |> Gen.map (fun (first, last) -> sprintf "%s %s" first last)
        |> Arb.fromGen

Answer 2

您正在为类型字符串定义一个新生成器，但在其中您正在使用string * string生成器，它使用string生成器。遗憾的是，FsCheck似乎将生成器存储在全局可变状态（可能有充分的理由？），我认为这意味着生成器会一直调用自己直到堆栈溢出。

您可以通过为自定义包装器类型而不是普通字符串定义生成器来解决此问题（如下所示）。

您将遇到的下一个问题是空引用异常。最初生成的字符串可能是null，您尝试访问.Length属性。这可以使用String.length函数来解决，它会为0返回null。

通过这些更改，您的生成器如下所示：

type Name = Name of string

type NameGen() =
    static member Name() =
        Arb.generate<string * string>
        |> Gen.where (fun (firstName, lastName) ->
            String.length firstName > 0 && String.length lastName > 0
        )
        |> Gen.map (fun (first, last) -> sprintf "%s %s" first last)
        |> Arb.fromGen
        |> Arb.convert Name (fun (Name n) -> n)

您的财产需要稍作修改：

let propertyTests (Name input) =
    let output = toInitials input
    output.EndsWith(".")

生成字符串时，Expecto FsCheck会出现堆栈溢出异常

2 个答案: