Question

因此，在其他语言中，静态方法可以访问静态成员，并且它们的可见性受类范围的限制。在fortran中，没有静态成员（如果我错了就纠正我）并且方法名称是全局可访问的，所以我甚至不能在不同的类中使用两个具有相同名称的静态方法。我认为“nopass”方法是“静态的”，但我甚至不确定该术语是否适用。鉴于上述情况，我认为只是简单的模块功能没有任何区别。使用nopass方法比普通函数有什么好处吗？

编辑：

无法在不同的类中使用两个具有相同名称的静态方法的说明：

module test_mod
  type type1
  contains
    procedure, nopass :: proc => proc1
  end type

  type type2
  contains
    procedure, nopass :: proc => proc2
  end type

contains
  subroutine proc1()
    print *, 'proc1'
  end subroutine

  subroutine proc2()
    print *, 'proc2'
  end subroutine
end module

显然，我现在不能只说call proc()，也不能使用类名来帮助编译器选择正确的方法。

Answer 1

考虑可访问性：只要可以访问类型，就可以访问公共类型绑定过程。

module mod
  private
  type, public :: type1
  contains
    procedure, nopass :: proc
  end type

contains

  subroutine proc
  end subroutine

end module

  use mod
  type(type1) t1

  call t1%proc
  call proc  ! No, we can't call proc from mod1

end

同样，使用use <module>, only <...>

module mod1
  type type1
  contains
    procedure, nopass :: proc
  end type

contains

  subroutine proc
  end subroutine

end module

module mod2
  type type2
  contains
    procedure, nopass :: proc
  end type

contains

  subroutine proc
  end subroutine

end module

我们可以避免模块过程名称中的冲突而不重命名使用关联：

  use mod1, only : type1
  use mod2, only : type2

  type(type1) t1
  type(type2) t2

  call t1%proc
  call t2%proc    ! These aren't ambiguous

end

为了避免程序含糊不清，我们必须重命名：

  use mod1, proc1=>proc
  use mod2, proc2=>proc

  call proc1
  call proc2

end

还有动态选择程序参考：

module mod
  type type1
  contains
    procedure, nopass :: proc=>proc1
  end type

  type, extends(type1) :: type2
  contains
    procedure, nopass :: proc=>proc2
  end type

contains

  subroutine proc1
  end subroutine

  subroutine proc2
  end subroutine

end module

use mod
class(type1), allocatable :: t

t=type1()
call t%proc  ! proc1

t=type2()
call t%proc  ! proc2

end

但应注意，t1%proc之类的绑定名称与过程名称不同

 use mod
 type(type1) t1
 call sub(proc1)    ! Where this is accessible
 call sub(t1%proc)  ! We cannot do this

contains

 subroutine sub(proc)
   procedure() proc
 end subroutine

end

fortran

1 个答案: