Question

我有一个像这样的xml代码段：

 <root>
    <order>
        <item>
            <item_type>A</item_type>
            <item_type>A</item_type>
            <item_type>B</item_type>
            <item_type>C</item_type>
        </item>
    </order>
    <order>
        <item>
            <item_type>A</item_type>
            <item_type>B</item_type>
            <item_type>C</item_type>
            <item_type>C</item_type>
        </item>
    </order>
    <order>
        <item>
            <item_type>C</item_type>
            <item_type>C</item_type>
            <item_type>B</item_type>
        </item>
    </order>
 </root>

我需要按item_type元素对其进行分组，但是在＆＃34; order＆＃34;元素范围，所以我想要的输出是：

 <root>
    <order>
        <item>A</item>
        <item>B</item>
        <item>C</item>
    </order>
    <order>
        <item>A</item>
        <item>B</item>
        <item>C</item>
    </order>
    <order>
        <item>B</item>
        <item>C</item>
    </order>
 </root>

我使用的是xslt 1.0版本，但我无法弄清楚。

 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
     version="1.0">
    <xsl:key name="groups" match="order/item" use="item_type">
    </xsl:key>
     <xsl:template match="/">
         <xsl:for-each select="//root/order">
             <order>                
                 <xsl:for-each select="item[generate-id() = generate-id(key('groups', item_type))]">
                     <item>
                         <xsl:value-of select="key('groups', item_type)"/>
                     </item>
                 </xsl:for-each>
             </order>
         </xsl:for-each>
     </xsl:template>
 </xsl:stylesheet>

解决方案必须在xslt 1.0中。

Answer 1

你有很多问题，最重要的问题是：

您想要对item_type进行分组，而不是item。这意味着您的密钥必须与item_type;
您想在order内对它们进行分组。这意味着您的密钥必须包含唯一的order标识符。

因此，您的密钥需要定义为：

<xsl:key name="groups" match="item_type" use="concat(., '|', generate-id(ancestor::order))"/>

此外，您的Muenchian分组语法错误。而且你没有输出根元素。

以这种方式尝试：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="groups" match="item_type" use="concat(., '|', generate-id(ancestor::order))"/>

<xsl:template match="/root">
    <root>
        <xsl:for-each select="order">
            <order>                
                <xsl:for-each select="item/item_type[generate-id() = generate-id(key('groups', concat(., '|', generate-id(ancestor::order)))[1])]">
                    <item>
                        <xsl:value-of select="."/>
                    </item>
                </xsl:for-each>     
            </order>
        </xsl:for-each>     
    </root>
</xsl:template>

</xsl:stylesheet>

应用于您的输入示例，结果将是：

<?xml version="1.0" encoding="UTF-8"?>
<root>
  <order>
    <item>A</item>
    <item>B</item>
    <item>C</item>
  </order>
  <order>
    <item>A</item>
    <item>B</item>
    <item>C</item>
  </order>
  <order>
    <item>C</item>
    <item>B</item>
  </order>
</root>

Answer 2

如果您只想使用XPath，可以使用它。

host:*some port other than 80*

xslt 1.0嵌套分组

2 个答案: