Question

我尝试预处理websocket传入消息。在lobby_channel.ex文件中我有：

defmodule Chatroom.LobbyChannel do
  use Phoenix.Channel

  def join("room:lobby", _payload, socket) do
    {:ok, socket}
  end
  def join("room:" <> _private_room_id, _params, _socket) do
    {:error, %{reason: "unauthorized"}}
  end

  def handle_in("new_move", payload, socket) do
    changeset = Chatroom.Move.changeset(%Chatroom.Move{}, payload)

    if changeset.valid? do
      broadcast! socket, "new_move", payload
      {:noreply, socket}
    else
      IO.puts "-----" <> changeset.errors[:message]
      push socket, "error", %{msg: "Invalid move"}
      {:noreply, socket}
    end
  end

  #intercept ["new_move"]
  #def handle_out("new_move", payload, socket) do
  #  IO.puts payload["name"] <> "=======" <> payload["message"]
  #  push socket, "new_move", payload
  #  {:noreply, socket}
  #end
end

模型文件包含验证函数：

...
def changeset(struct, params \\ %{}) do
  struct
  |> cast(params, [:name, :message])
  |> validate_required([:name, :message])
  |> validate_length(:name, min: 1)
  |> validate_length(:message, is: 2)
  |> is_move_allowed(params)
end

defp is_move_allowed(changeset, params) do
  IO.puts "--zz---" <> params["message"]

  if params["message"] == "00" do
    IO.puts "--yy---" <> params["message"]
    add_error(changeset, params["message"], "'message' cannot be '00'")
  else
    IO.puts "--xx---" <> params["message"]
    []
  end
end
...

..最后一个是我的自定义验证功能，我不能让它正常工作。我得到的输出：

--zz---00
--yy---00
[error] GenServer #PID<0.445.0> terminating
** (ArgumentError) argument error
    :erlang.byte_size(nil)
    (chatroom) web/channels/lobby_channel.ex:18: Chatroom.LobbyChannel.handle_in/3
    (phoenix) lib/phoenix/channel/server.ex:226: anonymous fn/4 in Phoenix.Channel.Server.handle_info/2
    (stdlib) gen_server.erl:601: :gen_server.try_dispatch/4
    (stdlib) gen_server.erl:667: :gen_server.handle_msg/5
    (stdlib) proc_lib.erl:247: :proc_lib.init_p_do_apply/3
Last message: %Phoenix.Socket.Message{event: "new_move", payload: %{"message" => "00", "name" => "a"}, ref: "2", to
pic: "room:lobby"}
State: %Phoenix.Socket{assigns: %{}, channel: Chatroom.LobbyChannel, channel_pid: #PID<0.445.0>, endpoint: Chatroom
.Endpoint, handler: Chatroom.UserSocket, id: nil, joined: true, pubsub_server: Chatroom.PubSub, ref: nil, serialize
r: Phoenix.Transports.WebSocketSerializer, topic: "room:lobby", transport: Phoenix.Transports.WebSocket, transport_
name: :websocket, transport_pid: #PID<0.439.0>}

据我了解，事情在逻辑上正确地移动，消息包含正确的数据，但我该如何修复错误？我错过了什么？

Answer 1

代码中有三个错误：

is_move_allowed必须始终返回变更集。您在其他地方返回[]。
add_error的第二个参数应该是原子
changeset.errors[:message]是一个元组，因此您无法使用<>将其与String连接。 IO.inspect是一个更好的选择，因为它会打印任何值。

所以，改变：

if params["message"] == "00" do
  IO.puts "--yy---" <> params["message"]
  add_error(changeset, params["message"], "'message' cannot be '00'")
else
  IO.puts "--xx---" <> params["message"]
  []
end

为：

if params["message"] == "00" do
  IO.puts "--yy---" <> params["message"]
  add_error(changeset, :message, "'message' cannot be '00'")
else
  IO.puts "--xx---" <> params["message"]
  changeset
end

并改变：

IO.puts "-----" <> changeset.errors[:message]

为：

IO.inspect changeset.errors[:message]
# or IO.inspect changeset.errors

“Elixir + phoenix”过滤websocket消息

1 个答案: