Question

我需要对字符串进行标记，然后在每个标记上运行analyze-string。然而，这似乎是不可能的：

＆＃34; XPTY0020：子轴的上下文项的必需项类型是node（）;提供的值具有项类型xs：string）因为 analyze-string需要节点上下文＆＃34;。

这让我感到疯狂，因为analyze-string应该好好分析字符串，所以我不明白如何解决这个问题。

我的（简化）XML看起来像这样：

<?xml version="1.0" encoding="UTF-8"?>
<rows>
    <row>
        <field name="def">1) ἀλλά sed, vero 2) καί et 3) а cum condicionali iunctum aequiparat
            аште: 4) ἵνα ut chron.</field>
    </row>
    <row>
        <field name="def">ἡλοῦν clavo figere</field>
    </row>
</rows>

我的样式表看起来像这样：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" version="2.0">

    <xsl:strip-space elements="*"/>
    <xsl:output omit-xml-declaration="no" indent="yes"/>

    <xsl:template match="field[@name = 'def']">
        <entry>
            <xsl:call-template name="sense">
                <xsl:with-param name="def" select="."/>
            </xsl:call-template>
        </entry>
    </xsl:template>

    <xsl:template name="sense">
        <xsl:param name="def"/>
        <xsl:param name="separator" select="'\d{1,2}\)\s'"/>

        <xsl:for-each select="tokenize(normalize-space($def), $separator)">
            <xsl:if test="string-length(.) > 0">
                <xsl:element name="sense">
                    <xsl:attribute name="n">
                        <xsl:value-of select="position() - 1"/>
                    </xsl:attribute>
                    <!--this is the problematic bit, because current() is 
                    a string here -\- and, paradoxically, analyze-string
                    cannot deal with it-->
                    <xsl:analyze-string select="current()"
                        regex="^([\p{IsGreek}\p{IsGreekExtended}]+[\s]*[\p{IsGreek}\p{IsGreekExtended}]*)(.*$)">
                        <xsl:matching-substring>
                            <greek>
                                <xsl:value-of select="regex-group(1)"/>
                                <xsl:value-of select="regex-group(2)"/>
                            </greek>
                        </xsl:matching-substring>
                        <xsl:non-matching-substring>
                            <xsl:value-of select="current()"/>
                        </xsl:non-matching-substring>
                    </xsl:analyze-string>
                </xsl:element>
            </xsl:if>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

如果没有analyze-string的问题，上面的样式表将正确生成以下输出：

<?xml version="1.0" encoding="UTF-8"?>
<entry xmlns:xs="http://www.w3.org/2001/XMLSchema">
   <sense n="1">ἀλλά sed, vero </sense>
   <sense n="2">καί et </sense>
   <sense n="3">а cum condicionali iunctum aequiparat аште: </sense>
   <sense n="4">ἵνα ut chron.</sense>
</entry>
<entry xmlns:xs="http://www.w3.org/2001/XMLSchema">
   <sense n="0">ἡλοῦν clavo figere</sense>
</entry>

样式表使用tokenize()方法分隔多个感官。然后，对于每个已识别的感官，我想使用analyze-string用<greek></greek>包装第一个希腊词。

我可以使用哪些解决方法使analyze-string处理令牌，即字符串而不是节点？

非常感谢提前！

Answer 1

我认为问题是regex属性允许使用属性值模板，所以你的大括号需要加倍才能说明

regex="^([\p{{IsGreek}}\p{{IsGreekExtended}}]+[\s]*[\p{{IsGreek}}\p{{IsGreekExtended}}]*)(.*$)"

或者您需要在变量中定义外部模式，例如

<xsl:variable name="pattern">^([\p{IsGreek}\p{IsGreekExtended}]+[\s]*[\p{IsGreek}\p{IsGreekExtended}]*)(.*$)</xsl:variable>

并使用regex="{$pattern}"。

使用标记化字符串

1 个答案: