Question

我试图加入Perl数组的元素。

@array=('a','b','c','d','e');
$string=join(']',@array);

会给我

$string="a]b]c]d]e";

无论如何我可以很快得到

$string="[a][b][c][d][e]";

Answer 1

另一种方法，使用sprintf。

my $str = sprintf '[%s]' x @array, @array;

Answer 2

以下是两个选项：

#!/usr/bin/perl

use strict;
use warnings;

my @array = 'a' .. 'e';
my $string = join('', map { "[$_]" } @array);
my $string1 = '[' . join('][', @array) . ']';

Answer 3

也许：

{
  local $" = "][";
  my @array = qw/a b c d e/;
  print "[@array]";
}

虽然你应该只是：

print "[" . join("][", @array) . "]";

快乐编码： - ）

Answer 4

#!/usr/bin/perl
use strict; use warnings;

local $" = '';
my $x = qq|@{[ map "[$_]", qw(a b c d e) ]}|;

你也可以稍微概括一下：

#!/usr/bin/perl
use strict; use warnings;

my @array = 'a' .. 'e';

print decorate_join(make_decorator('[', ']'), \@array), "\n";

sub decorate_join {
    my ($decorator, $array) = @_;
    return join '' => map $decorator->($_), @$array;
}

sub make_decorator {
    my ($left, $right) = @_;
    return sub { sprintf "%s%s%s", $left, $_[0], $right };
}

在Perl中，如何在将每个元素括在括号中之后连接数组的元素？

4 个答案: