Question

我需要为Prolog创建一个笛卡尔积计算器。它应该像这样工作：

输入：product([1,2,3], [a,b], X).

输出：X = [[1,a],[2,a],[3,a],[1,b],[2,b],[3,b]].

我知道互联网上有一些例子，但我想自己写一些东西。

这是我的代码，我认为它非常接近，但由于某种原因，它并没有完全奏效。任何想法，伙计们？

% call new with 4 parameters (so we can keep List1 in memory)
product(L1,L2,L3):- product(L1,L2,L3,L1).

% stop when both List1 and List2 are empty
product([], [], [], []).

% first list is empty, recreate it and work it again with the next element of second list (and shorten memory)
product([], [_|T2], List3, [H4|T4]):-
    product([H4|T4], T2, List3, T4).

%go through first list and always first element of second list to our answer
product([H1|T1], [H2|T2], [[H1,H2]|T3], List4):-
    product(T1, [H2|T2], T3, List4).

Answer 1

您应该更改条款：

product([], [], [], []).

为：

product(_, [], [], _).

那是因为当L2变空时它调用产品（L1，[]，L3，L4），其中L1和L4不为空。你的基本情况必须是当L2变空时（然后L3作为输出列表变为空），而其他列表可能有元素：

?- product([1,2,3], [a,b], X).
X = [[1, a], [2, a], [3, a], [1, b], [2, b], [3, b]] ;
false.

Answer 2

在SWI-Prolog中，也可以使用findall/3和member/2谓词生成笛卡尔积：

:- initialization(main).
:- use_module(library(chr)).

main :-
    product([1,2,3], [a,b], X),
    writeln(X).

product(A,B,C) :-
    findall([X,Y],(member(X,A),member(Y,B)),C).

此程序打印[[1,a],[1,b],[2,a],[2,b],[3,a],[3,b]]。

Answer 3

如编码器（+1）所述，您应该从

更改终端子句

product([], [], [], []).

到

product(_, [], [], _).

但还不够。

你从

转变第三条款

product([], [_|T2], List3, [H4|T4]):-
    product([H4|T4], T2, List3, T4).

到

product([], [_|T2], List3, L4):-
    product(L4, T2, List3, L4).

我的意思是：使用保存的列表1是一个错误。

使用您的版本，来自

product([1,2,3,4,5], [a,b,c,d], X),

你只得到

[[1,a],[2,a],[3,a],[4,a],[5,a],[1,b],[2,b],[3,b],[4,b],[5,b],[2,c],[3,c],[4,c],[5,c],[3,d],[4,d],[5,d]]

即：您放弃了[1,c]，[1,d]和[2,d]。

Prolog - 笛卡尔积计算器

3 个答案: