如何使用包含perioid的字符串从Groovy的GPathResult中检索元素

Question

def elementPath = "elementA.elementB"
xml."${elementPath}".each {}

如何使这项工作？ xml.elementA.elementB.each {}有效。

Answer 1

我可以想到两种方法......

// Dummy Data for the testing
def CAR_RECORDS = '''
    <records>
      <car name='HSV Maloo' make='Holden' year='2006'>
        <country>Australia</country>
        <record type='speed'>Production Pickup Truck with speed of 271kph</record>
      </car>
      <car name='P50' make='Peel' year='1962'>
        <country>Isle of Man</country>
        <record type='size'>Smallest Street-Legal Car at 99cm wide and 59 kg in weight</record>
      </car>
      <car name='Royale' make='Bugatti' year='1931'>
        <country>France</country>
        <record type='price'>Most Valuable Car at $15 million</record>
      </car>
    </records>
  '''
def xml = new XmlSlurper().parseText( CAR_RECORDS )
def propNames = 'car.country'

// METHOD 1
// Split the propnames into individual properties, then use Inject to walk down this list
// Passing the result to the next property
propNames.split( /\./ ).inject( xml ) { obj, prop -> obj?."$prop" }.each { println it.text() }

// METHOD 2
// Construct a string to evaluate, and pass the xml object to it (it gets substituted in place of x)
Eval.x( xml, "x.${propNames}" ).each { println it.text() }

javadoc page for Eval.x is here

希望这会有所帮助： - ）

Answer 2

xml."elementA.elementB".each {}