Question

如何在传递给函数时取消引用数组？

我这样做：

my @a = {\@array1, \@array2, \@array3};

func(\@a);


func{
    @b = @_;

    @c = @{@b};
}

实际上我希望数组@c应包含@array1，@array2和@array3的地址。

Answer 1

my @a = {\@array1, \@array2, \@array3};

以上是一个包含单个成员的数组 - ＆gt; 哈希包含：

{ ''.\@array1 => \@array2, ''.\@array3 => undef }

因为作为散列中的键，Perl将对@array1的引用强制转换为字符串。并且Perl允许将标量哈希引用分配给数组，因为“理解”您希望第一个元素是您分配给它的标量的数组。

您创建一个数组数组，如下所示：

my @a = (\@array1, \@array2, \@array3);

然后在你的函数中你将解压缩它们，如下：

sub func {
    my $ref = shift;
    foreach my $arr ( @$ref ) {
        my @list_of_values = @$arr;
    }
}

或者其中的一些变体，比如说地图将是最简单的表达方式：

my @list_of_entries = map { @$_ } @$ref;

在您的示例中，@c作为地址列表与正确构造的@a完全相同。

Answer 2

您可能需要阅读perldoc perlreftut，perldoc perlref和perldoc perldsc您可以说：

sub func {
    my $arrayref = shift;

    for my $aref (@$arrayref) {
        print join(", ", @$aref), "\n";
    }
}

my @array1 = (1, 2, 3);
my @array2 = (4, 5, 6);
my @array3 = (7, 8, 9);

my @a = \(@array1, @array2, @array3);

func \@a;

或更紧凑：

sub func {
    my $arrayref = shift;

    for my $aref (@$arrayref) {
        print join(", ", @$aref), "\n";
    }
}

func [ [1, 2, 3], [4, 5, 6], [7, 8, 9] ];

Answer 3

阅读perlreftut文档。

编辑：其他人指出了我最初错过的一个好点。在@a的初始化中，您可能意味着@a = (...)（创建包含引用的数组）或$arrayref = [...]（创建对数组的引用），而不是{...}（创建对哈希的引用）。本文的其余部分假装您拥有@a = (...)版本。

由于您将一个参数（对@a的引用）传递给func，因此@_是包含该一个引用的列表。您可以通过执行以下操作获取该引用然后取消引用：

sub func {
  my $arrayref = shift;
  my @c = @{$arrayref};
}

或者在一行中，它看起来像：

sub func {
  my @c = @{shift()};
}

（如果你没有在func(\@a)中使用反斜杠，@ _将等于@a，即三个引用的数组。）

Answer 4

以下函数旨在获取数组或数组引用，并返回唯一值的排序数组。删除未定义的值，并保留HASH和GLOB。

#!/usr/bin/perl
use strict; use warnings;

my @one = qw / dog rat / ;
my @two = qw / dog mice / ;
my @tre = ( "And then they said it!", "No!??  ", );
open my $H, '<', $0 or die "unable to open $0 to read";
my $dog; # to show behavior with undefined value
my %hash; $hash{pig}{mouse}=55; # to show that it leaves HASH alone
my $rgx = '(?is)dog'; $rgx = qr/$rgx/; # included for kicks

my @whoo =  (
    'hey!',
    $dog, # undefined
    $rgx,
    1, 2, 99, 999, 55.5, 3.1415926535,
    %hash,
    $H,
    [ 1, 2, 
              [ 99, 55, \@tre, ],
    3, ],
        \@one, \@two,
        [ 'fee', 'fie,' ,
            [ 'dog', 'dog', 'mice', 'gopher', 'piranha', ],
            [ 'dog', 'dog', 'mice', 'gopher', 'piranha', ],
        ],
        [ 1, [ 1, 2222, ['no!', 'no...', 55, ], ], ],
        [ [ [ 'Rat!', [ 'Non,', 'Tu es un rat!' , ], ], ], ], 
        'Hey!!',
        0.0_1_0_1,
        -33,
);


print join ( "\n", 
    recursively_dereference_sort_unique_array( [ 55, 9.000005555, ], @whoo, \@one, \@whoo, [ $H ], ),
    "\n", );
close $H;
exit;

sub recursively_dereference_sort_unique_array
{
    # recursively dereference array of arrays; return unique values sorted. Leave HASH and GLOB (filehandles) as they are.
    # 2020v10v04vSunv12h20m15s
    my $sb_name = (caller(0))[3];
    @_ = grep defined, @_; #https://stackoverflow.com/questions/11122977/how-do-i-remove-all-undefs-from-array
    my @redy = grep { !/^ARRAY\x28\w+\x29$/ } @_; # redy==the subset that is "ready"
    my @noty = grep {  /^ARRAY\x28\w+\x29$/ } @_; # noty==the subset that is "not yet"
    my $countiter = 0;
    while (1)
    {
        $countiter++; 
        die "$sb_name: are you in an infinite loop?" if ($countiter > 99);
        my @next;
        foreach my $refarray ( @noty )
        {
            my @tmparray = @$refarray;
            push    @next, @tmparray;
        }
        @next = grep defined, @next;
        my @okay= grep { !/^ARRAY\x28\w+\x29$/ } @next;
        @noty   = grep {  /^ARRAY\x28\w+\x29$/ } @next;
        push @redy, @okay;
        my %hash = map { $_ => 1 } @redy; # trick to get unique values
        @redy    = sort keys %hash;
        return @redy unless (scalar @noty);
    }
}

Answer 5

应该是

func {
    $b = shift;
}

如果您传递参考资料。希望有所帮助。

如何在Perl中取消引用数组数组？

5 个答案: