Question

syntax-parameterize通常与make-rename-transformer结合使用，以便语法参数p充当另一个标识符的别名：

#lang racket

(require racket/stxparam)
(define-syntax-parameter p #f)

(define-syntax (test-1-p stx)
  (syntax-case stx ()
    [(_ body)
     #'(let ([tmp 123])
         (syntax-parameterize ([p (make-rename-transformer #'tmp)])
           body))]))
(test-1-p p) ;; prints 123

上面的代码效果很好，因为tmp是由let绑定的标识符。但是，如果我尝试使p为tmp绑定的模式变量with-syntax的别名，则它无法正常工作：

#lang racket

(require racket/stxparam)
(define-syntax-parameter p #f)

(define-syntax (test-2-p stx)
  (syntax-case stx ()
    [(_ body)
     #'(with-syntax ([tmp #'(foo 123)])
         (syntax-parameterize ([p (make-rename-transformer #'tmp)])
           body))]))
(test-2-p #'p) ;; gives #'p, instead of #'(foo 123)

如果我声明p-unhygienic语法，并将其绑定到(make-rename-transformer #'tmp)，那么它可以正常工作：

#lang racket

(define-syntax (test-3-p stx)
  (syntax-case stx ()
    [(_ body)
     #`(with-syntax ([tmp #'(foo 123)])
         (define-syntax #,(syntax-local-introduce #'p-unhygienic)
           (make-rename-transformer #'tmp))
         body)]))
(test-3-p #'p-unhygienic) ;; gives #'(foo 123), as expected

如何使用syntax-parameterize？

为模式变量创建卫生别名

Answer 1

这是一个有趣的案例，我期待你做同样的事情。这可能是某个地方的错误或限制;我不确定。无论哪种方式，define-rename-transformer-parameter表单都是作为解决方法提供的。

rename-transformer-parameter的初始值必须是重命名变换器，因此您可以使用p-init标识符#f作为变换器绑定。

(define-syntax p-init #f)
(define-rename-transformer-parameter p (make-rename-transformer #'p-init))

在上下文中：

#lang racket

(require racket/stxparam)
(define-syntax p-init #f)
(define-rename-transformer-parameter p (make-rename-transformer #'p-init))

(define-syntax (test-2-p stx)
  (syntax-case stx ()
    [(_ body)
     #'(with-syntax ([tmp #'(foo 123)])
         (syntax-parameterize ([p (make-rename-transformer #'tmp)])
           body))]))
(test-2-p #'p) ; #<syntax:10:28 (foo 123)>

语法参数指向语法模式变量？

1 个答案: