Question

我对如何实现这一点感到困惑，或者它是否真的可行/适当。我的同事和我正在使用Grails 3为客户构建一个Web应用程序。他创建了初始域名，我猜测来自移动应用程序的Realm模型几乎一对一的副本。我自从修改它们以尝试通过某种形式的深度克隆工作，因为三个域具有一对多的关系。

问题

我如何创建域的深层副本？我尝试了建议的答案但收效甚微：

从各个地方挑选想法我已经开始制定如下所示的clone(Domain)方法。它几乎有效（我认为），但是有些问题会导致HibernateException - Found shared references to a collection: Location.equipments投放。

在控制器中调用：

def copy() {
    Survey.clone(Survey.get(params.id))
    redirect action: 'index'
}

任何想法或指导？

目前域名如下：

class Survey {

    int id
    String name
    String contactName
    String contactEmail
    String facilityAddress
    String facilityCity
    String facilityStateProvince
    String facilityZip
    String distributorName
    String distributorEmail
    String distributorPhoneNumber

    static Survey clone(Survey self) {
        Survey clone = new Survey()
        String exclude = "locations"

        clone.properties = self.properties.findAll {
            it.key != exclude
        }

        self.locations.each {
            Location copy = Location.clone it
            clone.addToLocations copy
        }

        clone.save()
    }

    static transients = ['clone']
    static belongsTo = User
    static hasMany = [locations: Location]
}

class Location {
    int id
    String name
    String[] hazardsPresent
    HazardType[] hazardTypes
    ExposureArea[] exposureArea
    RiskLevel exposureLevel
    String comments
    byte[] picture

    static Location clone(Location self) {
        Location clone = new Location()
        String[] excludes = ['equipment', 'products']

        clone.properties = self.properties.findAll {
            !(it.key in excludes)
        }

        self.equipments.each {
            Equipment copy = Equipment.clone it
            self.addToEquipments copy
        }

        self.products.each {
            RecommendedProduct copy = new RecommendedProduct()
            copy.properties = it.properties
            copy.save()
            clone.addToProducts copy
        }

        clone.save()
    }

    static transients = ['clone']
    static belongsTo = Survey
    static hasMany = [equipments: Equipment, products: RecommendedProduct]
    static constraints = {
        picture(maxSize: 1024 * 1024)
    }
}

class Equipment {
    int id
    EquipmentType type
    String name
    Brand brand

   // Redacted 26 boolean properties
   // ...

    static Equipment clone(Equipment self) {
        Equipment clone = new Equipment()
        String exclude = "extras"

        clone.properties = self.properties.findAll {
            it.key != exclude
        }

        self.extras.each {
            EquipmentQuestionExtra copy = new EquipmentQuestionExtra()
            copy.properties = it.properties
            copy.save()
            clone.addToExtras copy
        }

        clone.save()
    }

    static transients = ['clone']
    static belongsTo = Location
    static hasMany = [extras: EquipmentQuestionExtra]
}

class RecommendedProduct {
    int productId
    int quantityChosen
    String comment

    static belongsTo = Location
}

class EquipmentQuestionExtra {
    int id
    String questionText
    String comment
    byte[] picture

    static belongsTo = Equipment
    static constraints = {
        picture(maxSize: 1024 * 1024)
    }
}

Answer 1

您的克隆方法可能存在问题：您克隆“所有”属性，包括ID，这是深度克隆的一个坏主意。 This thread解释当一个对象具有与hibernate缓存中的另一个对象相同的属性时，抛出你的错误，但是另一个引用。

因此，您只需将对象的modalInstance.result.then(function (modalOutput) { if (modalOutput) { if ('okToUndoEdits' === modalOutput[1]) { $scope.chargebackDetail.cbDetails = angular.copy($scope.chargebackDetailBackup.cbDetails); } else if ('okToSaveUnmatched' === modalOutput[1]) { $('#noMatchWarning').show(); $scope.isMatchedDoc = false; } } }, function () { });属性设置为id（或将其从属性副本中排除）以强制hibernate检测到它是一个新对象。如果仍然无效，请在null之前调用对象上的discard方法。

Answer 2

已经差不多一年了，自从完成这个项目以来我已经解决了这个问题。

我想出的解决方案是使用service layer。我为每个域定义了一个服务。需要深层复制集合的任何域，称为其关联的服务方法。我只发布两个服务的来源，因为其他方法基本相同。

流程是这样的：

创建域的新空白实例。
复制所有＆＃39;原语＆＃39;通过String等Boolean，duplicate.properties = original.properties等属性。
由于上面也设置了collection / has-many关系，因此会产生关于共享集合的HibernateException。因此，请将集合设置为null。
调用关联的服务方法来复制collection / has-many。
保存并返回重复的域。

service/SurveyService.groovy

class SurveyService {
/**
 * Attempts to perform a deep copy of a given survey
 *
 * @param survey The survey instance to duplicate
 * @return The duplicated survey instance
 */
Survey duplicateSurvey(Survey originalSurvey) {
    Survey duplicatedSurvey = new Survey()

    duplicatedSurvey.properties = originalSurvey.properties
    duplicatedSurvey.locations = null
    duplicatedSurvey.uuid = UUIDGenerator.createUniqueId()
    duplicatedSurvey.dateModified = DateUtil.getCurrentDate()
    duplicatedSurvey.name = "${originalSurvey.name.replace("(copy)", "").trim()} (copy)"
    duplicatedSurvey.save()
    duplicatedSurvey.locations = duplicateLocations originalSurvey.locations, duplicatedSurvey
    duplicatedSurvey.save()
}

/**
 * Attempts to perform a deep copy of a survey's location
 *
 * @param originalLocations The original location set
 * @param duplicatedSurvey The duplicated survey that each survey will belong to
 * @return The duplicated location set
 */
Set<Location> duplicateLocations(Set<Location> originalLocations, Survey duplicatedSurvey) {
    Set<Location> duplicatedLocations = []

    for (originalLocation in originalLocations) {
        duplicatedLocations << locationService.duplicateLocation(originalLocation, duplicatedSurvey)
    }

    duplicatedLocations
}
}

service/LocationService.groovy

class LocationService {
    /**
     * Performs a deep copy of a given location. The duplicated location name is
     * the original location name and the duplicated location ID.
     *
     * @param originalLocation The location to duplicate
     * @param survey The survey that the location will belong to
     * @return The duplicated location
     */
    Location duplicateLocation(Location originalLocation, Survey survey = null) {
        Location duplicatedLocation = new Location()
        duplicatedLocation.properties = originalLocation.properties
        duplicatedLocation.survey = survey ?: duplicatedLocation.survey
        duplicatedLocation.uuid = UUIDGenerator.createUniqueId()
        duplicatedLocation.dateModified = DateUtil.currentDate
        duplicatedLocation.equipments = null
        duplicatedLocation.products = null
        duplicatedLocation.save()
        duplicatedLocation.name = "${originalLocation.name.replace("(copy)", "").trim()} (copy)"
        duplicatedLocation.equipments = duplicateEquipment originalLocation.equipments, duplicatedLocation
        duplicatedLocation.products = duplicateProducts originalLocation, duplicatedLocation
        duplicatedLocation.save()

        duplicatedLocation
    }

    /**
     * Performs a deep copy of a given locations equipments.
     *
     * @param originalEquipments The original locations equipments
     * @param duplicatedLocation The duplicated location; needed for belongsTo association
     * @return The duplicated equipment set.
     */
    Set<Equipment> duplicateEquipment(Set<Equipment> originalEquipments, Location duplicatedLocation) {
        Set<Equipment> duplicatedEquipments = []

        for (originalEquipment in originalEquipments) {
            Equipment duplicatedEquipment = new Equipment()
            duplicatedEquipment.properties = originalEquipment.properties
            duplicatedEquipment.uuid = UUIDGenerator.createUniqueId()
            duplicatedEquipment.dateModified = DateUtil.currentDate
            duplicatedEquipment.location = duplicatedLocation
            duplicatedEquipment.extras = null
            duplicatedEquipment.save()
            duplicatedEquipment.name = "${originalEquipment.name.replace("(copy)", "").trim()} (copy)"
            duplicatedEquipment.extras = duplicateExtras originalEquipment.extras, duplicatedEquipment
            duplicatedEquipments << duplicatedEquipment
        }

        duplicatedEquipments
    }

    /**
     * Performs a deep copy of a given locations extras.
     *
     * @param originalExtras The original location extras
     * @param duplicatedEquipment The duplicated equipment; needed for belongsTo association
     * @return The duplicated extras set.
     */
    Set<EquipmentQuestionExtra> duplicateExtras(Set<EquipmentQuestionExtra> originalExtras, Equipment duplicatedEquipment) {
        Set<EquipmentQuestionExtra> duplicatedExtras = []

        for (originalExtra in originalExtras) {
            EquipmentQuestionExtra duplicatedExtra = new EquipmentQuestionExtra()
            duplicatedExtra.properties = originalExtra.properties
            duplicatedExtra.equipment = duplicatedEquipment
            duplicatedExtra.uuid = UUIDGenerator.createUniqueId()
            duplicatedExtra.dateModified = DateUtil.currentDate
            duplicatedExtra.save()
            duplicatedExtras << duplicatedExtra
        }

        duplicatedExtras
    }

    /**
     * Performs a deep copy of a given locations products.
     *
     * @param originalLocation The original location
     * @param duplicatedLocation The duplicated location
     * @return The duplicated product set.
     */
    Set<RecommendedProduct> duplicateProducts(Location originalLocation, Location duplicatedLocation) {
        Set<RecommendedProduct> originalProducts = originalLocation.products
        Set<RecommendedProduct> duplicatedProducts = []

        for (originalProduct in originalProducts) {
            RecommendedProduct duplicatedProduct = new RecommendedProduct()
            duplicatedProduct.properties = originalProduct.properties
            duplicatedProduct.location = duplicatedLocation
            duplicatedProduct.uuid = UUIDGenerator.createUniqueId()
            duplicatedProduct.dateModified = DateUtil.currentDate
            duplicatedProduct.save()
            duplicatedProducts << duplicatedProduct
        }

        duplicatedProducts
    }
}

Answer 3

您正在保存子实体。不要那样做，只保存实体Survey（root）。其他人将通过级联保存。

另一方面，正如@Joch所说，在这种情况下使用克隆不是正确的方法。

您应该为您的实体创建一个重复的方法。以下是如何克隆此结构类型的示例。这是一个有n个问题的测试，每个问题都有n个答案，每个类都有一个“重复”方法。

class Test {

    String name

    static hasMany = [
            /**
             * Each question of the test
             */
            questions: Question
    ]

    /**
     * Duplicates this test
     */
    Test duplicate(){
         Test test = new Test(name:this.name)
         this.questions.each{ question ->
             test.addToQuestions(question.duplicate(test))
         }
         test
    }
}


class Question {

    Integer questionOrder
    String title

    /**
     * Each question belong to a Test
     */
    static belongsTo = [test:Test]

    static hasMany = [
            /**
             * Each answer of the test
             */
            answers: Answer
    ]

    /**
     * Duplicates this test to another edition
     * @param edition to be duplicated
     * @return duplicated question
     */
    Question duplicate(Test test){
        if(test){
            Question question = new Question(title:this.title)
            this.answers.each{ answer->
                question.addToAnswers(answer.duplicate())
            }
            test.addToQuestions(question)
            question
        }
    }
}

class Answer {

    String title
    boolean correct
    /**
     * Each answer belongs to a question
     */
    static belongsTo = [question:Question]

    /**
     * Duplicates this answer to another question
     * @param edition to be duplicated
     * @return duplicated question
     */
    Answer duplicate(){
        Answer answer = new Answer()
        answer.properties['title','correct'] = this.properties['title','answerOrder','correct']
        answer
    }
}

在Answer.duplicate（）中，您有一个如何从其他对象绑定某些属性的示例。

Grails 3中一对多域的深层副本

3 个答案: