Question

假设我有一个像这样的单位

unit sample;

interface

function Test1:Integer;
procedure Test2;

implementation

function Test1:Integer;
begin
 result:=0;
end;

procedure Test2;
begin

end;

end.

是否可以在运行时枚举单元sample的所有过程和函数？

Answer 1

没有。不为独立方法生成RTTI。希望这将在以后的版本中修复，（他们可能需要一个TRttiUnit类型来执行此操作），但是现在它不可用。

Answer 2

您可以使用JCL及其出色的JclDebug.pas从某种调试信息（TD32，Map文件，Jdbg等）中提取该信息。

试试这个：

uses
  JclDebug;

type
  TProc = record
    name: string;
    addr: Pointer;
  end;

  TProcArray = array of TProc;
  TMapLoader = class
  private
    FModule: Cardinal;
    FProcs: TProcArray;
    FMapFileName: string;
    FUnitName: string;
    procedure HandleOnPublicsByValue(Sender: TObject; const Address: TJclMapAddress; const Name: string);
  public
    constructor Create(const AFileName: string; AModule: Cardinal; const AUnitName: string);
    procedure Scan();
    property Procs: TProcArray read FProcs;
  end;

constructor TMapLoader.Create(const AFileName: string; AModule: Cardinal; const AUnitName: string);
begin
  inherited Create;
  FMapFileName := AFileName;
  FModule := AModule;
  FUnitName := AUnitName;
end;

procedure TMapLoader.HandleOnPublicsByValue(Sender: TObject; const Address: TJclMapAddress; const Name: string);
var
  l: Integer;
begin
  if Pos(FUnitName + '.', Name) = 1 then
  begin
    l := Length(FProcs);
    SetLength(FProcs, l + 1);
    FProcs[l].name := Name;
    FProcs[l].addr := Pointer(Address.Offset + FModule + $1000);
  end;
end;

procedure TMapLoader.Scan();
var
  parser: TJclMapParser;
begin
  parser := TJclMapParser.Create(FMapFileName, FModule);
  try
    parser.OnPublicsByValue := HandleOnPublicsByValue;
    parser.Parse;
  finally
    parser.Free;
  end;
end;

Answer 3

我不这么认为。

这是一个编译时配置，它被使用，因为编译器知道正在调用哪个函数名。据我所知，在运行时没有任何内容可以接近列出这些函数。

Delphi优秀的运行时功能来自RTTI，您可能希望看到它提供的相关内容。但正如我所说，我不认为这是可能的（知道我已经花了很长时间研究RTTI ......）。

编辑：哦，顺便说一句，编译后，函数会丢失人类可读的名称（到地址）。有些表将这些名称精确定位到地址，最值得注意的是RTTI和调试信息。

使用delphi枚举单元的全局方法

3 个答案: