Question

我试图找到一种方法来识别数字变量子集，这些数字变量表示来自包含许多数字或字符类型变量的任意数据集的日期，时间或日期时间。目标是拥有一个可以针对任何给定数据集运行的宏或模板。我相信这些变量的SAS格式应该正确地表示变量是什么，但我试图看看是否可以避免必须创建一些代码来解析任何适用格式名称的SAS格式文本

我原本以为应该可以执行以下操作来获取数据集的SAS格式，然后根据作为日期/时间/日期时间返回的列执行各种操作。

PROC SQL;
   CREATE TABLE lib_X.Dataset_A AS
   SELECT tbl_CL.LIBNAME
         ,tbl_CL.MEMNAME AS TABLE_NAME
         ,tbl_CL.NAME    AS COLUMN_NAME
         ,tbl_CL.FORMAT  AS SAS_Format
         ,tbl_CL.TYPE    AS SAS_Type
         ,tbl_CL.varnum
         ,tbl_CL.LENGTH
   FROM DICTIONARY.COLUMNS AS tbl_CL
   WHERE tbl_CL.MEMNAME = %UPCASE("&SAS_DatasetNm")
     AND tbl_CL.LIBNAME = %UPCASE("&SAS_LibNm");
QUIT;

其次是：

DATA lib_X.Dataset_A;
   SET lib_X.Dataset_A;
   IF FCN_FORMAT_TYPE(SAS_Format) = "DATETIME" 
   THEN ...;
RUN;

FCN_FORMAT_TYPE函数是一个检查SAS格式并返回4 categories of SAS Format（字符，数字，日期/时间或ISO 8601）变量的函数，但是没有＆＃ 39; t似乎是我能找到的现有功能。也许还有另一种方法可行吗？

目前在Linux服务器上运行SAS 9.4 M2。代码主要通过批处理文件使用，但也可能通过Enterprise Guide（EG 7.1或6.1）

Answer 1

没有开箱即用的解决方案，但这是一个可行的解决方案。

为简单起见，我们只使用日期，不包括时间和日期时间格式。该解决方案可以很容易地概括为包括那些。

作为第一步，您可以设计出可以选择合理日期格式的过滤器。以下是一个匹配大约100种SAS日期格式的查询示例。

proc sql;
  create table fmts as
  select fmtname
    from sashelp.vformat
   where fmttype = "F"
         and fmtname not like '$%'
         and prxmatch("/(DATE|YY|YEAR)/",fmtname)
         and not prxmatch("/(DT|TIME)/",fmtname)
   order by fmtname;
quit;

一旦你对WHERE过滤器进行了微调，你就可以在如下的宏例程中使用它，其中第三个参数vmname是你希望存储日期列的全局宏变量的名称名字在。。

%macro getDateCols(libname, dataset, vmname);

  %global &vmname;

  proc sql noprint;
    select name
      into :&vmname separated by ", " /* Use ", " or " " depending on your needs */
      from dictionary.columns
     where libname = upcase("&libname")
           and memname = upcase("&dataset")
           and format not like '$%'
           and prxmatch("/(DATE|YY|YEAR|MONTH|DAY|WEEK)/", format)
           and not prxmatch("/(DT|TIME)/", format);
  quit;

%mend getDateCols;

调用宏后，您应该在&dsdates中获取列名 HireDate ：

%getDateCols(sasuser, empdata, dsdates);
%put &dsdates;

然后你可以在proc sql中使用宏变量，例如......

proc sql;
  select &dsdates 
   from sasuser.empdata;
quit;

Answer 2

多米尼克的答案给了我一个关于如何解决它的想法，使用相同的一般方法，但把它放在PROC FCMP函数而不是宏。

PROC FCMP OUTLIB=LIB_X.FCMP_FUNCS.Format_Category_ID;
   FUNCTION Format_Category(VAR_Format $, VAR_Type $) $ 16
        GROUP = 'Format Category ID'
        LABEL = 'Pass SAS variable type and format as CHAR and it will return what sort of variable it is. 
                 Breaks down date/time/dt formats into independent categories.';
        LENGTH FORMAT_CATEGORY $16;
        SELECT;
            WHEN        (MISSING(VAR_Format))                                                   FORMAT_CATEGORY = 'MISSING_FORMAT';
            WHEN        (VAR_Type = 'CHAR')                                                     FORMAT_CATEGORY = 'CHARACTER_FORMAT';
            WHEN        (PRXMATCH("/S370FZDT/", VAR_Format))                                    FORMAT_CATEGORY = 'NUMERIC_FORMAT';
            WHEN        (PRXMATCH("/8601/", VAR_Format))                                        FORMAT_CATEGORY = 'ISO_8601_FORMAT';
            WHEN        (PRXMATCH("/(DT|DATEAMPM|DATETIME)/", VAR_Format))                      FORMAT_CATEGORY = 'DATETIME_FORMAT';
            WHEN        (PRXMATCH("/(HHMM|HOUR|MMSS|TIME|TOD)/", VAR_Format))                   FORMAT_CATEGORY = 'TIME_FORMAT';
            WHEN        (PRXMATCH("/(DAT|DAY|YY|DOW|JUL|MON|QTR|WEEK|YEAR)/", VAR_Format))      FORMAT_CATEGORY = 'DATE_FORMAT';
            WHEN        (VAR_Type = 'NUM')                                                      FORMAT_CATEGORY = 'NUMERIC_FORMAT';
            OTHERWISE                                                                           FORMAT_CATEGORY = 'UNKNOWN';
        END;
        RETURN(FORMAT_CATEGORY);
   ENDSUB;

它绝对不是防弹，但它适用于我的目的，并希望对其他人有用。我要补充的最大的一点是，处理用户定义的格式将会触及，因为它只是解析作为字符变量传递的SAS格式，所以如果名称与我正在使用的正则表达式重叠，则所有赌注不在了。

SAS - 以编程方式识别表示日期/时间/日期时间的数字变量

2 个答案: