Question

我有一个问题，表有100行。它会导致出现问题，需要将其拆分为几个较小的表，每个表的行数较少。

我的html也是有效的xml。

如何将每x行的表拆分成一个新表？

并且，如何将表格样式和第一行（标题）复制到每个后续表格中。

这样的事情

<table class="..." style="...">
   <tr>
       <td>head 1</td>
       <td>head 2</td>
   </tr>

   <tr>
       <td>col1</td>
       <td>col2</td>
   </tr>

   <tr>
       <td>col1</td>
       <td>col2</td>
   </tr>

   <tr>
       <td>col1</td>
       <td>col2</td>
   </tr>

   <tr>
       <td>col1</td>
       <td>col2</td>
   </tr>

   <tr>
       <td>col1</td>
       <td>col2</td>
   </tr>

   <tr>
       <td>col1</td>
       <td>col2</td>
   </tr>
<table>

变为

<table class="..." style="...">
   <tr>
       <td>head 1</td>
       <td>head 2</td>
   </tr>

   <tr>
       <td>col1</td>
       <td>col2</td>
   </tr>

   <tr>
       <td>col1</td>
       <td>col2</td>
   </tr>
</table>

<table class="..." style="...">
   <tr>
       <td>head 1</td>
       <td>head 2</td>
   </tr>

   <tr>
       <td>col1</td>
       <td>col2</td>
   </tr>

   <tr>
       <td>col1</td>
       <td>col2</td>
   </tr>
</table>

<table class="..." style="...">
   <tr>
       <td>head 1</td>
       <td>head 2</td>
   </tr>

   <tr>
       <td>col1</td>
       <td>col2</td>
   </tr>

</table>

<table class="..." style="...">
   <tr>
       <td>head 1</td>
       <td>head 2</td>
   </tr>
   <tr>
       <td>col1</td>
       <td>col2</td>
   </tr>
<table>

Answer 1

对于此类问题，这是经典的XSLT 1.0解决方案：

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:param name="prowLimit" select="12"/>

    <xsl:variable name="vTable" select="/*"/>

 <xsl:template match="node()|@*" name="identity">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="tr">
  <xsl:if test="position() mod $prowLimit = 1">
    <table>
      <xsl:copy-of select="$vTable/@*"/>
      <xsl:copy-of select=
      ". | following-sibling::tr[not(position() > $prowLimit -1)]"/>
    </table>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

Answer 2

这是一个使用for-each-group的XSLT2解决方案。要更改每个表的项数，请更改组相邻属性中的除数。使用Saxon 9.2在Oxygen / XML中测试。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:xd="http://www.oxygenxml.com/ns/doc/xsl"
  exclude-result-prefixes="xs xd"
  version="2.0">
  <xsl:output method="xml" indent="yes"/>
  <xsl:template match="table">
    <xsl:variable name="tblNode" select="."/>
    <xsl:variable name="header"  select="tr[1]"/>
    <xsl:for-each-group select="tr[position() > 1]" group-adjacent="(position()-1) idiv 3">
      <xsl:element name="table">
        <xsl:copy-of select="$tblNode/@*"/>
        <xsl:copy-of select="$header"/>
        <xsl:apply-templates select="current-group()"/>
      </xsl:element>
    </xsl:for-each-group>
  </xsl:template>
  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

说明：

在“table”模板中为表节点本身创建一个变量，因此我们可以稍后复制其属性，并将包含第一行的变量重新用作标题。
使用for-each-group选择相邻的集合，其中“position（） - 1 idiv 3”的结果给出相同的结果。对于前三行，它返回0;对于接下来的三个，结果是1，依此类推。除数控制将每组中的行数分组。
对于每个集合，生成一个表元素，然后复制所有原始表的属性，然后复制标题行，然后使用标识模板（在样式表的末尾）复制所有行。

请注意，如果您在行中有嵌套表，则必须稍微修改它以避免“table”模板与内部表匹配。

Answer 3

这个XSLT 1.0样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:param name="pMaxRow" select="2"/>
    <xsl:template match="/">
        <html>
            <xsl:apply-templates
                 select="table/tr[(position()-1) mod $pMaxRow = 1]"
                 mode="table"/>
        </html>
    </xsl:template>
    <xsl:template match="node()|@*" name="identity">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="tr" mode="table">
        <table>
            <xsl:apply-templates select="../@*|../tr[1]|.|following-sibling::tr
                                             [$pMaxRow > position()]"/>
        </table>
    </xsl:template>
</xsl:stylesheet>

输出：

<html>
    <table class="..." style="...">
        <tr>
            <td>head 1</td>
            <td>head 2</td>
        </tr>
        <tr>
            <td>col1</td>
            <td>col2</td>
        </tr>
        <tr>
            <td>col1</td>
            <td>col2</td>
        </tr>
    </table>
    <table class="..." style="...">
        <tr>
            <td>head 1</td>
            <td>head 2</td>
        </tr>
        <tr>
            <td>col1</td>
            <td>col2</td>
        </tr>
        <tr>
            <td>col1</td>
            <td>col2</td>
        </tr>
    </table>
    <table class="..." style="...">
        <tr>
            <td>head 1</td>
            <td>head 2</td>
        </tr>
        <tr>
            <td>col1</td>
            <td>col2</td>
        </tr>
        <tr>
            <td>col1</td>
            <td>col2</td>
        </tr>
    </table>
</html>

修改：压缩代码。

将大表拆分为几个较小的表

3 个答案: