Question

给出以下xml文档：

<XML>
<doc1>
</doc1>
<doc2>
</doc2>
<XML>

我希望使用xsl转换来生成2个XML文档：

<XML>
<doc1>
</doc1>
<XML>

和

<XML>
</doc2>
<doc2>
<XML>

这可能吗？

Answer 1

在XSLT 1.0中，不可能创建多个树作为任何转换的输出，但在XSLT 2.0中，这可以非常简单。

在XSLT 1.0中，可以使用EXSLT的 <exsl:document> 扩展元素。

或者，可以进行转换，即提供一个全局（和外部指定）参数，该参数包含必须提取到单个文档中的元素的元素名称：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pDocElement" select="'doc1'"/>

 <xsl:template match="/*/*">
  <xsl:if test="name()=$pDocElement">
   <xsl:apply-templates select="." mode="copy"/>
  </xsl:if>
 </xsl:template>

 <xsl:template match="node()" mode="copy">
  <xsl:copy-of select="."/>
 </xsl:template>

 <xsl:template match="text()"/>
</xsl:stylesheet>

应用于此XML文档时（基于提供的文档）：

<t>
    <doc1>
  Doc 1 Content
    </doc1>
    <doc2>
  Doc 2 Content
    </doc2>
    <doc3>
  Doc 3 Content
    </doc3>
</t>

生成了想要的结果：

<doc1>
  Doc 1 Content
</doc1>

您将为每个元素运行此转换，其子树应提取到单独的文档中。

这是一个XSLT 2.0解决方案：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="node()|@*" mode="copy">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="/*/*[starts-with(name(),'doc')]">
  <xsl:result-document href="{name()}.xml">
   <xsl:apply-templates select="." mode="copy"/>
  </xsl:result-document>
 </xsl:template>

 <xsl:template match="/*">
  <xsl:apply-templates/>
 </xsl:template>
</xsl:stylesheet>

对以下XML文档应用此转换时（基于提供的转换）：

<t>
    <doc1>
  Doc 1 Content
    </doc1>
    <doc2>
  Doc 2 Content
    </doc2>
    <doc3>
  Doc 3 Content
    </doc3>
</t>

结果正确输出到三个文档：

Saxon 9.1.0.5J from Saxonica
Java version 1.6.0_21
Stylesheet compilation time: 868 milliseconds
Loading net.sf.saxon.event.MessageEmitter
Writing to file:/C:/Program%20Files/Java/jre6/bin/doc1.xml
Writing to file:/C:/Program%20Files/Java/jre6/bin/doc2.xml
Writing to file:/C:/Program%20Files/Java/jre6/bin/doc3.xml
Execution time: 151 milliseconds
Memory used: 11467936
NamePool contents: 18 entries in 18 chains. 6 prefixes, 6 URIs

Answer 2

我们曾经遇到过这个问题并通过轻微作弊解决了这个问题：

步骤1：创建一个包含由程序指令或注释分隔的不同xml脚本的大文件。第2步：使用程序将文件剪切成单独的文件。

请注意，您的中间结果是无效的xml，但最终结果是有效的。

示例

<doc1>..<doc1>  <doc2>..<doc2>  <doc3>..<doc3>

使用xsl将单个XML文档转换为多个文档

2 个答案: