Question

使用很好的语法在actionscript中实现经典咖喱函数的最佳方法是什么？

我试过了：

Function.prototype.curry = function()
{
return "helloWorld";
}

trace((function():void {}).curry());

......接近但是没有用。

我想我一直坚持使用丑陋的方法，例如：

FunctionUtils.curry(fp, ... args)

???

Answer 1

我必须承认，我从未理解“咖喱”和“偏袒”之间的区别。我使用以下函数来执行或多或少的操作：

package {
  public function partial( func : Function, ...boundArgs ) : Function {
    return function( ...dynamicArgs ) : * {
      return func.apply(null, boundArgs.concat(dynamicArgs))
    }
  }
}

用法示例：

var multiply : Function = function( a : Number, b : Number ) : Number { return a * b; }
var multiplyByFour : Function = partial(multiply, 4);

trace(multiplyByFour(3)); // => 12

Answer 2

结束（受到dojo实施的极大启发）：

public static function curry(func:Function, ... args:Array):*
{
    var arity:int = func.length;
    var currying:Function = function(func:Function, arity:int, args:Array):*
    {
        return function(... moreArgs:Array):* {
            if(moreArgs.length + args.length < arity)
            {
                return currying(func, arity, args.concat(moreArgs));
            }
            return func.apply(this, args.concat(moreArgs));
        }
    }
    return currying(func, arity, args);
}

在评论部分请求显示如何使用它的示例：

function foo(i:int, j:int):void
{
   trace(i+j);
}

function bar(fp:Function):void
{
   fp(2);
}

bar(FunctionUtils.curry(foo, 1)); //trace==3

愚蠢的例子，我知道，但咖喱：非常有用。看一下http://www.svendtofte.com/code/curried_javascript/的理论。

Flex：在actionscript中实现经典的curry功能？

2 个答案: