Question

在我目前正在处理的TCL代码中，每个过程中的参数都是upvar到局部变量，可以说，然后使用。像这样：

proc configure_XXXX { params_name_abc params_name_xyz} {
    upvar $params_name_abc abc
    upvar $params_name_xyz xyz
}

从此开始， abc 和 xyz 将用于做任何事情。我读了upvar TCL wiki，但无法理解其优点。我的意思是为什么我们只能使用已经接收的变量作为过程中的参数。有人可以详细说明吗？

Answer 1

我的意思是为什么我们只能使用已经作为过程中的参数接收的变量。

你可以。它只是让人讨厌。

通常，当您将变量的 name 传递给命令时，命令可以修改该变量。这方面的经典示例是set和incr命令，它们都将变量的名称作为它们的第一个参数。

set thisVariable $thisValue

您也可以使用过程执行此操作，但是当需要从过程的调用程序的上下文中定义的变量（可能是命名空间或可能的变量）时，您需要从过程的上下文中访问变量。是一个不同的局部变量框架。为此，我们通常使用upvar，它将局部变量的别名变为另一个上下文中的变量。

例如，这是incr的重新实现：

proc myIncr {variable {increment 1}} {
    upvar 1 $variable v
    set v [expr {$v + $increment}]
}

为什么写入局部变量v会导致调用者上下文中的变量更新？因为我们已将其别名（在内部，它通过指向另一个变量的存储结构的指针设置;一旦upvar完成，它就会非常快）。 global和variable使用相同的基础机制;他们都归结为快速变量别名。

如果你使用uplevel，你可以不用，但这会更烦人：

proc myIncr {variable {increment 1}} {
    set v [uplevel 1 [list set $variable]]
    set v [expr {$v + $increment}]
    uplevel 1 [list set $variable $v]
}

那太讨厌了！

或者，假设我们根本没有这样做。然后我们需要通过它的值传递变量，然后分配结果：

proc myIncr {v {increment 1}} {
    set v [expr {$v + $increment}]
    return $v
}

# Called like this
set foo [myIncr $foo]

有时是正确的事，但是完全不同的工作方式！

Tcl的核心原则之一是，您可以使用标准库命令（例如if或puts或incr）完成任何操作。你自己写的命令。没有关键字。当然可能存在一些效率问题，并且某些命令可能需要用另一种语言（例如C）才能正常工作，但语义不会使任何命令特殊。他们所有只是简单的命令。

Answer 2

upvar命令允许您修改块中的变量，并使此修改从父块可见。

试试这个：

# a function that will modify the variable passed
proc set_upvar { varname } {
    upvar 1 $varname var
    puts "var was $var\n"
    set var 5
    puts "var is now $var\n"
}

# a function that will use the variable but that will not change it
proc set_no_upvar { var } {
    puts "var was $var\n"
    set var 6
    puts "var is now $var\n"
}

set foo 10

# note the lack of '$' here
set_upvar foo
puts "foo is $foo\n"

set_no_upvar $foo
puts "foo is $foo\n"

Answer 3

正如上面的评论中提到的，它通常用于通过引用传递函数参数（通过引用调用）。一张图片要花费千言万语：

proc f1 {x} {
    upvar $x value
    set value 0
}

proc f2 {x} {
    set x 0
}

set x 1
f1 x
puts $x

set x 1
f2 x
puts $x

将导致：

$ ./call-by-ref.tcl
  0
  1

使用upvar我们更改了函数之外的变量x（从1更改为0），而我们没有更改upvar。

upvar的目的是什么？

3 个答案: