我创建了一个.bat文件，该文件捕获其目录中的所有.log文件，并将它们全部编译为一个.csv文件。我希望它在编译时省略而不是删除每个文件的前5行，从而保留原始文件并将行留在生成的.csv文件中。
请注意：我只是使用.csv文件来保存已编译的.log文件。我知道预期的结果与实际的.csv文件没有任何相似之处，我将在excel中处理文件以分离值。
.LOG文件（'表示要删除的行 - 实际上不存在于文件中的这些行中）：
'20160201
'Time Side Serial # Active Current Idle Current OK/NOK
'----------- -------- --------------- ------------------- -------------- ---
'
'
00:00:23 Left 4EEFD9 6.59418mA 0.00003mA OK
00:00:23 Right 4EEFEF 6.85377mA 0.00001mA OK
.CSV输出文件：
00:00:23 Left 4EEFD9 6.59418mA 0.00003mA OK
00:00:23 Right 4EEFEF 6.85377mA 0.00001mA OK
00:00:44 Left 4EEFDC 6.32207mA 0.00004mA OK
00:00:44 Right 4EEF77 6.66909mA 0.00006mA OK
00:01:00 Left 4EEFB1 6.31158mA 0.00001mA OK
00:01:00 Right 4EEFA5 6.54818mA 0.00003mA OK
00:01:17 Left 4EEFA9 6.52762mA 0.00006mA OK
这是我使用的代码：
rem Script to process .log files to remove first five lines.
for %%I in (*.log) do for /f "delims=, tokens=* skip=5" %%x in (%%I) do echo %%x >> "%%I.new"
rem Script to compile .log files into .csv file.
for %%f in (*.log.new) do CALL :label "%%f" "results.csv"
:label
set resultfile=%2
type %1 >> %resultfile%
echo ; >> %resultfile%
exit/b
它设法以我想要的方式处理.log文件，但这需要永远，因为每个文件包含接近10,000行，批处理器将每行复制到新文件。是否有更好的方法让它简单地忽略前5行？
编辑1：
合并Aacini提供的原始批处理脚本可提供以下结果：
C:\Users\...\Desktop>set /P "="
C:\Users\...\Desktop>set /P "="
C:\Users\...\Desktop>set /P "="
C:\Users\...\Desktop>set /P "="
C:\Users\...\Desktop>set /P "="
00:00:23 Left 4EEFD9 6.59418mA 0.00003mA OK
00:00:23 Right 4EEFEF 6.85377mA 0.00001mA OK
00:00:44 Left 4EEFDC 6.32207mA 0.00004mA OK
00:00:44 Right 4EEF77 6.66909mA 0.00006mA OK
...
注意：处理器不再能运行多个.log文件。它在第一个文件后停止执行。此时我必须运行两个.bat文件。首先使用Aacini的代码（见他的答案），然后是这个，因为我无法将两者结合起来：
rem Script to compile .log files into .csv file.
for %%f in (*.log) do CALL :label "%%f" "results.csv"
:label
set resultfile=%2
type %1 >> %resultfile%
echo ; >> %resultfile%
exit/b
使用Aacini的更新代码我获得了与原始代码相同的结果并且速度更快，但是它仍然在第一个.log文件之后停止，而.csv文件的最后一行现在显示以下内容：Terminate batch job (Y/N)?
编辑2：
使用dbenham的第一个代码解决方案，我获得了与原始代码相同的结果。但是，第二个代码给出了这个结果：
C:\Users\...\Desktop>(
for /F "skip=5 usebackq delims=" %L in ("20160201.log") do echo(%L
echo ;
)
C:\Users\...\Desktop>echo(00:00:23 Left 4EEFD9 6.59418mA 0.00003mA OK
00:00:23 Left 4EEFD9 6.59418mA 0.00003mA OK
C:\Users\...\Desktop>echo(00:00:23 Right 4EEFEF 6.85377mA 0.00001mA OK
00:00:23 Right 4EEFEF 6.85377mA 0.00001mA OK
C:\Users\...\Desktop>echo(00:00:44 Left 4EEFDC 6.32207mA 0.00004mA OK
00:00:44 Left 4EEFDC 6.32207mA 0.00004mA OK
第三个代码给出了这个结果：
C:\Users\...\Desktop>(
more +5 "20160201.log"
echo ;
)
00:00:23 Left 4EEFD9 6.59418mA 0.00003mA OK
00:00:23 Right 4EEFEF 6.85377mA 0.00001mA OK
00:00:44 Left 4EEFDC 6.32207mA 0.00004mA OK
00:00:44 Right 4EEF77 6.66909mA 0.00006mA OK
编辑3：
我错过了@echo off。 dbenham更新的第3个脚本可以解决问题。
答案 0 :(得分：3)
我认为这是“将* .log文件中除了前5个文件以外的所有行复制到* .log.new文件中”的最快方法：
for %%I in (*.log) do (
rem Read from this file
< "%%I" (
rem Omit the first 5 lines
for /L %%a in (1,1,5) do set /P "="
rem Copy the rest
findstr "^"
rem And create the new file
) > "%%I.new"
)
也许如果您向我们展示最终.csv输出文件的格式，我们也可以帮助您以更快的方式创建它......
编辑：以下代码是我猜生成OP所需的results.csv输出文件：
@echo off
(for %%I in (*.log) do (
rem Read from this file
< "%%I" (
rem Omit the first 5 lines
for /L %%a in (1,1,5) do set /P "="
rem Copy the rest
findstr "^"
)
echo ;
)) > results.csv
答案 1 :(得分：1)
我无法理解你为什么使用中间文件。并且您的代码定义了str变量，但从不使用它。
除非你有更多重要的代码没有分享，否则我相信你需要的是:(注意，我保留你的输出名称，但你显示的输出是 不是< CSV格式的/ em> 。）
@echo off
for %%F in (*.log) do (
for /f "skip=5 delims=" %%L in (%%F) do echo %%L >>results.csv
echo ; >>results.csv
)
只需重定向一次即可显着提高性能。我假设您要从空输出文件开始，因此单个重定向允许您使用>而不是>>。我做了很多其他改动以提高可靠性。
@echo off
>results.csv (
for %%F in (*.log) do (
for /f "skip=5 usebackq delims=" %%L in ("%%F") do echo(%%L
echo ;
)
)
假设您的日志文件不包含TAB字符，并且没有单个日志文件超过~64,000行，那么您可以使用MORE跳过每个文件的前5行。这很多更快。
@echo off
>results.csv (
for %%F in (*.log) do (
more +5 "%%F"
echo ;
)
)
MORE将不会暂停，因为输出已重定向到文件，但如果超过~64,000行，它将暂停。任何TAB字符都将转换为一系列空格。