Question

我想要一个vbscript.vbs，它会为光标添加沙漏或完全将光标更改为沙漏，并且光标在脚本结束时更改为标准模式。

我经常搜索谷歌，但没有找到任何东西。我甚至没有尝试过一行代码。

Answer 1

VBS不包含此功能。

默认情况下.vbs文件由Windows脚本宿主执行，它不提供更新光标的方法。如果您正在使用其他主机，则可能会提供方法。

假设您正在寻找跟踪脚本进度的方法，则有一些解决方法。

方法1

通过命令行执行脚本会提供一个UI，您可以将进度输出到。

方法2

将您的VBScript包装在HTA内。这将提供单页HTML UI。您可以在此处添加某种进度指示器。

Answer 2

正如他所说 “目标数据” ==＆gt; VBS不包含此功能。

但是如果你将你的VBScript包装在HTA中，你可以找到一个解决方法

<强> Here is an example in HTA found here

<HTML>
  <HEAD>
    <STYLE>
      .clsAccKey:first-letter {text-decoration: underline}
      BUTTON {width: 15ex}
    </STYLE>
    <SCRIPT language=VBScript>
      Option Explicit

      Sub btnClick_onclick()
        btnClick.disabled = True
        document.body.style.cursor = "wait"
        btnClick.style.cursor = "wait"
        'Long delay here just to simulate a long
        'running process visually for this demo.
        setTimeout "HiThere", 2000, "VBScript"
      End Sub

      Sub HiThere()
        document.body.style.cursor = "default"
        btnClick.style.cursor = "default"
        MsgBox "Hi There!"
        btnClick.disabled = False
      End Sub
    </SCRIPT>
  </HEAD>
  <BODY>
    <BUTTON id=btnClick accessKey=C class=clsAccKey>Click Me</BUTTON>
  </BODY>
</HTML>

我在这个例子中使用过它：用HTA执行powershell文件

<html>
<head>
<title>Execution a powershell file with HTA by Hackoo</title>
<HTA:APPLICATION 
     APPLICATIONNAME="Execution a powershell file with HTA by Hackoo"
     SCROLL="yes"
     SINGLEINSTANCE="yes"
     WINDOWSTATE="maximize"
     ICON="Winver.exe"
     SCROLL="no"
/>
<script language="VBScript">
Option Explicit
Sub Run_PS_Script()
    ExampleOutput.value = ""
    btnClick.disabled = True
    document.body.style.cursor = "wait"
    btnClick.style.cursor = "wait"
    Dim WshShell,Command,PSFile,return,fso,file,text,Temp
    Set WshShell = CreateObject("WScript.Shell")
    Temp = WshShell.ExpandEnvironmentStrings("%Temp%")
    Command = "cmd /c echo Get-WmiObject Win32_Process ^| select ProcessID,ProcessName,Handle,commandline,ExecutablePath ^| Out-File %temp%\output.txt -Encoding ascii > %temp%\process.ps1"
    PSFile = WshShell.Run(Command,0,True)
    return = WshShell.Run("powershell.exe -ExecutionPolicy Unrestricted -File %temp%\process.ps1", 0, true)
    Set fso  = CreateObject("Scripting.FileSystemObject")
    Set file = fso.OpenTextFile(Temp &"\output.txt", 1)
    text = file.ReadAll 
    ExampleOutput.Value=text
    file.Close
    document.body.style.cursor = "default"
    btnClick.style.cursor = "default"
    btnClick.disabled = False   
End Sub
</script>
</head>
<body bgcolor="123456">
<textarea id="ExampleOutput" style="width:100%" rows="37"></textarea>
<br>
<center><input type="button" name="btnClick" value="Run powershell script file " onclick="Run_PS_Script()"></center> 
</body>
</html>

是否可以在光标上添加沙漏？

2 个答案: