Question

有没有办法在XMPP中查询用户状态，因为用户的订阅类型是“两者”？

由于我正在构建移动平台，因此我使用隐私列表阻止了所有传入的状态节。在我的用例中，用户至少会订阅500个用户并处理这些存在的节将给移动设备带来很大的压力。

因此，我不想处理所有用户节，而是仅在我查询时才能获得用户的存在。

Answer 1

ejabberd目前没有这样的功能，但这绝对是你可以作为插件开发的东西。您可以编写一个插件，使用HTTP Web服务器处理http请求，并在回复用户状态之前执行您想要的任何处理和安全检查。

Answer 2

为了将来参考，我已经设法将一些代码（感谢mod_last.erl）汇总在一起，并构建一个模块，让您查询用户存在。建议＆amp;反馈将受到高度赞赏。

-module(mod_query_presence).
-behaviour(gen_mod).

-export([start/2, stop/1,
    process_sm_iq/3
]).

-include("ejabberd.hrl").
-include("jlib.hrl").
-include("logger.hrl").

-include("mod_privacy.hrl").

-define(NS_QUERY_PRESENCE, <<"jabber:iq:qpresence">>).

start(Host, Opts) ->
    IQDisc = gen_mod:get_opt(iqdisc, Opts, fun gen_iq_handler:check_type/1,
                             one_queue),
    gen_iq_handler:add_iq_handler(ejabberd_sm, Host, 
                                  ?NS_QUERY_PRESENCE, ?MODULE, process_sm_iq, IQDisc),
    ?INFO_MSG("Loading module 'mod_iqtest' v.01", []).

stop(Host) ->
    gen_iq_handler:remove_iq_handler(ejabberd_sm, Host, ?NS_QUERY_PRESENCE),
    ?INFO_MSG("Stoping module 'mod_iqtest' ", []).

process_sm_iq(From, To,
              #iq{type = Type, sub_el = SubEl} = IQ) ->
    case Type of
      set ->
          IQ#iq{type = error, sub_el = [SubEl, ?ERR_NOT_ALLOWED]};
      get ->
          User = To#jid.luser,
          Server = To#jid.lserver,
          Resource = xml:get_tag_attr_s(list_to_binary("resource"), SubEl), 
          {Subscription, _Groups} =
              ejabberd_hooks:run_fold(roster_get_jid_info, Server,
                                      {none, []}, [User, Server, From]),
          if (Subscription == both) or (Subscription == from) or
               (From#jid.luser == To#jid.luser) and
                 (From#jid.lserver == To#jid.lserver) ->
                 UserListRecord =
                     ejabberd_hooks:run_fold(privacy_get_user_list, Server,
                                             #userlist{}, [User, Server]),
                 case ejabberd_hooks:run_fold(privacy_check_packet,
                                              Server, allow,
                                              [User, Server, UserListRecord,
                                               {To, From,
                                                #xmlel{name = <<"presence">>,
                                                       attrs = [],
                                                       children = []}},
                                               out])
                     of
                   allow -> get_presence(IQ, SubEl, User, Server, Resource);
                   deny ->
                       IQ#iq{type = error, sub_el = [SubEl, ?ERR_FORBIDDEN]}
                 end;
             true ->
                 IQ#iq{type = error, sub_el = [SubEl, ?ERR_FORBIDDEN]}
          end
    end.

get_presence(IQ, SubEl, LUser, LServer, LResource) ->
  case ejabberd_sm:get_session_pid(LUser, LServer, LResource) of
        none ->
            IQ#iq{type = error,
                      sub_el = [SubEl, ?ERR_SERVICE_UNAVAILABLE]};
        Pid ->
            {_U, _Resource, Status, StatusText} = ejabberd_c2s:get_presence(Pid),
            IQ#iq{type = result,
                    sub_el =
                          [#xmlel{name = <<"query">>,
                              attrs =
                                  [{<<"xmlns">>, ?NS_QUERY_PRESENCE},
                                   {<<"status">>, Status},
                                   {<<"StatusText">>, StatusText}],
                                   children = []}]}
    end.

IQ请求格式

<iq id='id' to='56876c654366178e0e75a8cd@192.168.1.150' type='get'>
    <query xmlns='jabber:iq:qpresence' resource='Smack'/>
</iq>

如果用户在线，则为IQ回复格式

<iq from='56876c654366178e0e75a8cd@192.168.1.150' to='56876c654366178e0e75a8cd@192.168.1.150/Smack' id='last1' type='result'>
    <query xmlns='jabber:iq:qpresence' status='dnd' StatusText='YO'/>
</iq>

如果用户不在线，您将收到服务不可用错误。

xmpp ejabberd - 查询用户状态

2 个答案: