START-OF-SELECTION未在我的计划中被触发。我正在尝试使用ABAP中的多个选择屏幕根据书名和书籍作者获取书籍详细信息。有两个按钮，基于这些选择屏幕打开。单击任何按钮时，将打开选择屏幕。但是，在从下拉列表中选择条目并单击执行按钮后，事务将使用按钮进入初始屏幕。书籍详细信息根本不显示。 START-OF-SELECTION未被触发。请帮忙，我是ABAP的新手。这是我的程序
REPORT y_multiple_screen.
TABLES: sscrfields.
TYPE-POOLS: vrm.
DATA: param TYPE vrm_id,
values TYPE vrm_values,
wa_value LIKE LINE OF values.
DATA: it_ybook TYPE TABLE OF ybook,
wa_ybook TYPE ybook.
FIELD-SYMBOLS: <fs_book> TYPE ybook.
SELECTION-SCREEN BEGIN OF BLOCK blocker WITH FRAME TITLE text-001 NO INTERVALS.
SELECTION-SCREEN SKIP.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN PUSHBUTTON (30) w_butn1 USER-COMMAND but1.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN SKIP.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN PUSHBUTTON (30) w_butn2 USER-COMMAND but2.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN SKIP.
SELECTION-SCREEN END OF BLOCK blocker.
SELECTION-SCREEN BEGIN OF SCREEN 1100.
PARAMETERS: p_author TYPE char255 AS LISTBOX VISIBLE LENGTH 20.
SELECTION-SCREEN END OF SCREEN 1100.
SELECTION-SCREEN BEGIN OF SCREEN 1200.
PARAMETERS: p_bname TYPE char255 AS LISTBOX VISIBLE LENGTH 20.
SELECTION-SCREEN END OF SCREEN 1200.
INITIALIZATION.
w_butn1 = 'Search by author name'.
w_butn2 = 'Search by book name'.
"At selection-screen output.
AT SELECTION-SCREEN.
IF sscrfields-ucomm EQ 'BUT1'.
CALL SELECTION-SCREEN 1100.
ELSEIF sscrfields-ucomm EQ 'BUT2'.
CALL SELECTION-SCREEN 1200.
ENDIF.
AT SELECTION-SCREEN OUTPUT.
CLEAR it_ybook.
SELECT *
FROM ybook
INTO TABLE it_ybook.
CLEAR values.
CLEAR wa_ybook.
CLEAR wa_value.
LOOP AT it_ybook INTO wa_ybook.
wa_value-key = wa_ybook-book_author.
wa_value-text = wa_ybook-book_author.
APPEND wa_value TO values.
CLEAR wa_ybook.
CLEAR wa_value.
ENDLOOP.
CLEAR it_ybook.
CALL FUNCTION 'VRM_SET_VALUES'
EXPORTING
id = 'P_AUTHOR'
values = values
EXCEPTIONS
id_illegal_name = 1
OTHERS = 2.
CLEAR it_ybook.
SELECT *
FROM ybook
INTO TABLE it_ybook.
"CLEAR values.
CLEAR wa_ybook.
CLEAR wa_value.
LOOP AT it_ybook INTO wa_ybook.
wa_value-key = wa_ybook-book_name.
wa_value-text = wa_ybook-book_name.
APPEND wa_value TO values.
CLEAR wa_ybook.
CLEAR wa_value.
ENDLOOP.
CLEAR it_ybook.
CALL FUNCTION 'VRM_SET_VALUES'
EXPORTING
id = 'P_BNAME'
values = values
EXCEPTIONS
id_illegal_name = 1
OTHERS = 2.
START-OF-SELECTION.
WRITE:/10 'Book ID',40 'Book Name',70 'Book Author',100 'Book Price'.
CLEAR it_ybook.
CLEAR wa_ybook.
SELECT *
FROM ybook
INTO TABLE it_ybook
WHERE book_name = p_bname.
LOOP AT it_ybook INTO wa_ybook.
WRITE:/10 wa_ybook-book_id,40 wa_ybook-book_name,70 wa_ybook-book_author,100 wa_ybook-book_price.
CLEAR wa_ybook.
ENDLOOP.
WRITE:/10 'Book ID',40 'Book Name',70 'Book Author',100 'Book Price'.
CLEAR it_ybook.
CLEAR wa_ybook.
SELECT *
FROM ybook
INTO TABLE it_ybook
WHERE book_author = p_author.
LOOP AT it_ybook INTO wa_ybook.
WRITE:/10 wa_ybook-book_id,40 wa_ybook-book_name,70 wa_ybook-book_author,100 wa_ybook-book_price.
CLEAR wa_ybook.
ENDLOOP.
答案 0 :(得分：2)
START-OF-SELECTION只会触发你的主屏幕（当你在第一个屏幕上点击执行时）。
您可以通过更改AT SELECTION-SCREEN块强制执行此事件：
AT SELECTION-SCREEN.
IF sscrfields-ucomm EQ 'BUT1'.
CALL SELECTION-SCREEN 1100.
if sy-subrc = 0. "the user clicked the execute button
sscrfields-ucomm = 'ONLI'. "set the system command for the next screen to execute
endif.
ELSEIF sscrfields-ucomm EQ 'BUT2'.
CALL SELECTION-SCREEN 1200.
if sy-subrc = 0. "the user clicked the execute button
sscrfields-ucomm = 'ONLI'. "set the system command for the next screen to execute
endif.
ENDIF.
答案 1 :(得分：0)
你可以在没有START-OF-SELECTION阻止的情况下实现这一目标
首先，将用户命令添加到参数中：
PARAMETERS: p_author TYPE char255 AS LISTBOX VISIBLE LENGTH 20 USER-COMMAND auth.
PARAMETERS: p_bname TYPE char255 AS LISTBOX VISIBLE LENGTH 20 USER-COMMAND name.
然后将您的下拉代码移至INITIALIZATION阻止：
INITIALIZATION.
w_butn1 = 'Search by author name'.
w_butn2 = 'Search by book name'.
CLEAR it_ybook.
SELECT *
FROM ybook
...
...
CALL FUNCTION 'VRM_SET_VALUES'
EXPORTING
id = 'P_BNAME'
values = values
EXCEPTIONS
id_illegal_name = 1
OTHERS = 2.
然后纠正AT-SELECTION-SCREEN这样的事件：
AT SELECTION-SCREEN.
CASE sscrfields-ucomm.
WHEN 'BUT1'.
CALL SELECTION-SCREEN 1100.
WHEN 'BUT2'.
CALL SELECTION-SCREEN 1200.
WHEN 'AUTH'.
LEAVE TO LIST-PROCESSING.
SET PF-STATUS space.
SUPPRESS DIALOG.
WHEN 'NAME'.
LEAVE TO LIST-PROCESSING.
SET PF-STATUS space.
SUPPRESS DIALOG.
WHEN OTHERS.
ENDCASE.
并将输出编码放在这里。您的列表将在下拉列表中选择值时正确输出。
请记住，默认情况下，选择屏幕参数会转换为大写，因此输出选择将不会返回上面给定表单中的行。因此，为了正确使用，您应该将它们转换为小写，如下所示：
TRANSLATE p_author TO LOWER CASE.
UPDATE：
LEAVE-TO-LIST-PROCESSING statement中断当前的Dynpro序列处理（但完成当前的Dynpro！）并切换到AS上缓冲的列表，直到那一刻。您应该在此处了解有关list processing的更多信息。这种技术已被废弃，但是，正如您选择的那样，您应该知道它:) SET PF-STATUS space设置列表的默认对话框状态。您可以从documentation了解对话状态。
您的代码有什么问题，您可以将2个循环语句合并为一个。另一个建议是在输出期间消除数据库选择：您不需要在此处进行任何数据修改，因此数据在INITIALIZATION阻止后不会发生变化。最后，您可以加强字段符号的使用，因为与工作区域相比，它们消耗的资源更少。因此，您的代码应如下所示：
INITIALIZATION。
TYPE-POOLS: vrm.
DATA: it_ybook TYPE TABLE OF ybook.
DATA: param TYPE vrm_id,
values_auth TYPE vrm_values,
values_name TYPE vrm_values,
wa_value_auth TYPE LINE OF vrm_values,
wa_value_name TYPE LINE OF vrm_values.
FIELD-SYMBOLS: <fs_ybook> TYPE ybook.
w_butn1 = 'Search by author name'.
w_butn2 = 'Search by book name'.
CLEAR: it_ybook, wa_value_auth, wa_value_name.
SELECT *
FROM ybook
INTO TABLE it_ybook.
LOOP AT it_ybook ASSIGNING <fs_ybook>.
wa_value_auth-key = <fs_ybook>-book_author.
wa_value_auth-text = <fs_ybook>-book_author.
wa_value_name-key = <fs_ybook>-book_name.
wa_value_name-text = <fs_ybook>-book_name.
APPEND wa_value_auth TO values_auth.
APPEND wa_value_name TO values_name.
ENDLOOP.
CALL FUNCTION 'VRM_SET_VALUES' "for authors
CALL FUNCTION 'VRM_SET_VALUES' "for names
选择屏幕。
CASE sscrfields-ucomm.
...
ENDCASE.
TRANSLATE P_BNAME TO LOWER CASE.
LOOP AT it_ybook ASSIGNING <fs_ybook> WHERE book_name = P_BNAME.
WRITE:/10 'Book ID',40 'Book Name',70 'Book Author',100 'Book Price'.
WRITE:/10 <fs_ybook>-book_id,40 <fs_ybook>-book_name,70 <fs_ybook>-book_author,100 <fs_ybook>-book_price.
ENDLOOP.
TRANSLATE P_AUTHOR TO LOWER CASE.
LOOP AT it_ybook ASSIGNING <fs_ybook> WHERE book_author = P_AUTHOR.
WRITE:/10 'Book ID',40 'Book Name',70 'Book Author',100 'Book Price'.
WRITE:/10 <fs_ybook>-book_id,40 <fs_ybook>-book_name,70 <fs_ybook>-book_author,100 <fs_ybook>-book_price.
ENDLOOP.