Question

如果我对问题的描述不清楚或过于复杂，我会提前道歉。我只是想确定我包含问题的所有方面。

我有一个场景，我收到对架构有效的XML文档，让我们称之为S1，看起来像这样（简化）：

<?xml version="1.0" encoding="utf-8"?>
    <xs:schema
        targetNamespace="http://somename.org/original"
        xmlns="http://somename.org/original"
        xmlns:xs="http://www.w3.org/2001/XMLSchema"
        xmlns:imported="http://somename.org/originalimported"
        elementFormDefault="unqualified">

    <xs:import namespace="http://somename.org/originalimported"/>

    <xs:element name="someElement">
        <xs:complexType>
            <xs:sequence>
                <xs:element ref="imported:someelement" />
            </xs:sequence>
        </xs:complexType>
    </xs:element>
</xs:schema>

正如你所看到的，它会导入另一个看起来像这样的命名空间（也简化了）并从中引用一个元素：

<?xml version="1.0" encoding="UTF-8"?>
<xs:schema
    targetNamespace="http://somename.org/originalimported"
    xmlns="http://somename.org/originalimported"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    version="1.0"
    elementFormDefault="unqualified">

    <xs:element name="someelement">
        <xs:complexType>
            ...
        </xs:complexType>
    </xs:element>

</xs:schema>

我还有两个其他模式“镜像”上面两个模式，唯一的区别是命名空间“http://somename.org/original”被替换为“http://somename.org/new”和命名空间“http://somename.org/originalimported”替换为“http://somename.org/newimported”。除此之外完全相同。看起来像这样（让我们称之为S2）：

<?xml version="1.0" encoding="utf-8"?>
<xs:schema
        targetNamespace="http://somename.org/new"
        xmlns="http://somename.org/new"
        xmlns:xs="http://www.w3.org/2001/XMLSchema"
        xmlns:imported="http://somename.org/newimported"
        elementFormDefault="unqualified">

    <xs:import namespace="http://somename.org/newimported"/>

    <xs:element name="someElement">
        <xs:complexType>
            <xs:sequence>
                <xs:element ref="imported:someelement" />
            </xs:sequence>
        </xs:complexType>
    </xs:element>

</xs:schema>

...和导入的：

<?xml version="1.0" encoding="UTF-8"?>
<xs:schema
    targetNamespace="http://somename.org/newimported"
    xmlns="http://somename.org/newimported"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    version="1.0"
    elementFormDefault="unqualified">

    <xs:element name="someelement">
        <xs:complexType>
            ...
        </xs:complexType>
    </xs:element>

</xs:schema>

我需要做的是转换我收到的任何文档，并对其进行转换并对其进行转换，以便对S2进行验证。这样做最可靠，最快捷的方法是什么？我重申一种方法是简单地在XML文档中使用字符串替换来替换实际的命名空间，但如果文档很大，这似乎不是最有效的方式。

必须使用C＃中提供的方法（包括XML / schema / XSLT类）完成实际转换。

提前致谢！

Answer 1

您可以使用

之类的方法

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0"
  xmlns:input1="http://example.com/original"
  xmlns:input2="http://example.com/originalimported"
  exclude-result-prefixes="input1 input2">

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="input1:*">
  <xsl:element name="{name()}" namespace="http://example.com/new">
    <xsl:apply-templates select="@* | node()"/>
  </xsl:element>
</xsl:template>

<xsl:template match="input2:*">
  <xsl:element name="{name()}" namespace="http://example.com/newimported">
    <xsl:apply-templates select="@* | node()"/>
  </xsl:element>
</xsl:template>

</xsl:stylesheet>

但是我希望看到一些示例文档来拼出并测试它。特别是elementFormDefault="unqualified"可能意味着里面的其他元素没有命名空间，上面会用范围内的父命名空间复制它们，这可能不是你想要的，所以也许这样做

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0"
  xmlns:input1="http://example.com/original"
  xmlns:input2="http://example.com/originalimported"
  exclude-result-prefixes="input1 input2">

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="*">
  <xsl:element name="{name()}" namespace="{namespace-uri()}">
    <xsl:apply-templates select="@* | node()"/>
  </xsl:element>
</xsl:template>

<xsl:template match="input1:*">
  <xsl:element name="{name()}" namespace="http://example.com/new">
    <xsl:apply-templates select="@* | node()"/>
  </xsl:element>
</xsl:template>

<xsl:template match="input2:*">
  <xsl:element name="{name()}" namespace="http://example.com/newimported">
    <xsl:apply-templates select="@* | node()"/>
  </xsl:element>
</xsl:template>

</xsl:stylesheet>

更好。

至于提供名称空间作为参数，我建议采用以下方法：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

<xsl:param name="input-ns1" select="'http://example.com/original'"/>
<xsl:param name="output-ns1" select="'http://example.com/new'"/>

<xsl:param name="input-ns2" select="'http://example.com/originalimported'"/>
<xsl:param name="output-ns2" select="'http://example.com/newimported'"/>

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="*">
  <xsl:element name="{name()}" namespace="{namespace-uri()}">
    <xsl:apply-templates select="@* | node()"/>
  </xsl:element>
</xsl:template>

<xsl:template match="*[namespace-uri() = $input-ns1]">
  <xsl:element name="{name()}" namespace="{$output-ns1}">
    <xsl:apply-templates select="@* | node()"/>
  </xsl:element>
</xsl:template>

<xsl:template match="*[namespace-uri() = $input-ns2]">
  <xsl:element name="{name()}" namespace="{$output-ns2}">
    <xsl:apply-templates select="@* | node()"/>
  </xsl:element>
</xsl:template>

</xsl:stylesheet>

但是我忘记了在XSLT 1.0中，不允许匹配模式使用变量引用，这样只有使用像Saxon 9或XmlPrime这样的XSLT 2.0处理器才能使用该方法。

在两个模式之间转换XML文档，仅在名称空间中有所不同

1 个答案: