Question

我制作了这个批处理文件，根据文本文件创建ZIP文件：

@echo off

set path="C:\Program Files\WinRAR\";%path%

for /f "tokens=1* delims=;" %%a in (list.txt) do (
    WinRAR a -afzip "%%a" %%b
    pause
    cls
)

文件list.txt如下所示：

file1.zip;fileA.pdf fileB.pdf fileC.pdf
file2.zip;fileA.pdf fileB.pdf fileC.pdf fileD.pdf
file3.zip;fileB.pdf fileD.pdf
file4.zip;fileA.pdf fileC.pdf fileE.pdf
file5.zip;file*.pdf

如你所见：

%%a是要创建的ZIP文件的名称，例如：file1.zip和
%%b是要添加到ZIP文件的文件列表，例如：fileA.pdf fileB.pdf fileC.pdf file1.zip。

效果非常好，但我想知道是否可以告诉我无法找到哪些文件（因此没有添加到ZIP文件中）对于每个创建的ZIP文件。

有什么想法吗？

编辑：正如@Mofi所述，Rar不能用于创建ZIP文件。所以我改变了

    rar a -r -m5 "%%a" %%b

到

    WinRAR a -afzip "%%a" %%b

Answer 1

....
for /f "tokens=1* delims=;" %%a in (list.txt) do ( 

   for %%f in (%%b) do if not exist %%f echo %%f does not exist

   WinRAR a -afzip "%%a" %%b
 ....

应该显示丢失的文件。

运行实际代码以验证：

@ECHO OFF
SETLOCAL
PUSHD "u:\sourcedir\t w o"
dir
ECHO ---------------------------------

FOR /f "tokens=1*delims=;" %%a IN (c:q33944403.txt) DO (
   for %%f in (%%b) do if not exist %%f echo %%f does not EXIST
   ECHO yourcompressor options "%%a" %%b
   ECHO ---------------------------------
)

popd

GOTO :EOF

结果：

 Directory of u:\sourcedir\t w o

28/11/2015  01:01    <DIR>          .
28/11/2015  01:01    <DIR>          ..
28/11/2015  01:05                 0 dum myfile2.txt
28/11/2015  01:05                 0 file1.zip
28/11/2015  01:05                 0 fileA.pdf
28/11/2015  01:05                 0 fileB.pdf
28/11/2015  01:05                 0 file2.zip
28/11/2015  01:05                 0 fileD.pdf
28/11/2015  01:05                 0 file3.zip
28/11/2015  01:05                 0 file4.zip
28/11/2015  01:05                 0 fileE.pdf
               9 File(s)              0 bytes
               2 Dir(s)   2,134,933,504 bytes free
---------------------------------
fileC.pdf does not EXIST
yourcompressor options "file1.zip" fileA.pdf fileB.pdf fileC.pdf
---------------------------------
fileC.pdf does not EXIST
yourcompressor options "file2.zip" fileA.pdf fileB.pdf fileC.pdf fileD.pdf
---------------------------------
yourcompressor options "file3.zip" fileB.pdf fileD.pdf
---------------------------------
fileC.pdf does not EXIST
yourcompressor options "file4.zip" fileA.pdf fileC.pdf fileE.pdf
---------------------------------

评论：

目录“u：\ sourcedir \ t w o \”只是一个测试目录。请注意，它包含OP列表中除FileC.pdf

之外的所有文件

Pushd / popd只需导航到该目录并返回。

我用作数据源（OP的list.txt）的文件是c:q33944403.txt，其中包含与运行报告中报告的数据相同的数据。

所以 - 它对我来说很完美！

Answer 2

控制台版本Rar不支持ZIP格式，因为它可以在文本文件%ProgramFiles%\WinRAR\Rar.txt中读取，这是控制台版本的手册。只有GUI版本WinRAR支持创建和提取ZIP存档。

没有必要使用 WinRAR 单独测试是否存在要归档的所有文件，因为这个评论的批处理代码演示了：

@echo off
rem Define name of error log file in directory for temporary files with name
rem of batch file, an underscore, a random number and file extension TMP.
set "ErrorLog=%TEMP%\%~n0_%RANDOM%.tmp"

rem Delete error log file if already existing from a previous run of this
rem batch file broke by the user while running and having randomly the
rem same number.
if exist "%ErrorLog%" del "%ErrorLog%"

rem For each ZIP file run WinRAR with ignoring default configuration (-cfg-)
rem using best compression (-m5), running in background (-ibck = minimized
rem to system tray), writing error messages into a log file (-ilog) and
rem suppressing displaying the errors in a GUI window (-inul).

rem If WinRAR really output any error into the log file, clear screen, output
rem on which ZIP file the error(s) occurred, output the logged error messages,
rem delete the error log file, and hold batch processing until user presses
rem any key to continue.

for /f "tokens=1* delims=;" %%a in (list.txt) do (
    "%ProgramFiles%\WinRAR\WinRAR.exe" a -afzip -cfg- -m5 -ibck "-ilog%ErrorLog%" -inul -- "%%~a" %%b
    if exist "%ErrorLog%" (
        cls
        echo Errors output by WinRAR on creating %%a:
        echo.
        type "%ErrorLog%"
        del "%ErrorLog%"
        echo.
        echo.
        pause
    )
)

rem Delete the environment variable for error log file name with path.
set "ErrorLog="

有关使用过的 WinRAR 开关

的更多详细信息

启动 WinRAR ，
点击帮助主题

帮助

在标签目录上打开命令行模式，
打开商品切换和
点击上述批次代码中使用的开关（选项/参数）。

重要的是不要使用-r开关（递归），因为这意味着 WinRAR 存档名称后的参数可以是文件或目录。

WinRAR v5.21不报告压缩时不存在的目录，只报告由于根本不存在而无法打开读取的文件，或者当前用户没有读取权限（NTFS分区），或由文件等其他正在运行的进程设置的读/写锁定。操作系统返回的文件打开错误的原因也由 WinRAR 输出，另外还有关于打开文件失败的错误消息。

WinRAR 期望没有-r归档文件名后的每个参数都是文件名（带或不带路径），因此如果文件无法打开则会输出错误消息用于阅读数据。

但该参数也可以是使用开关-r时不存在的目录的名称， WinRAR 不会将其报告为错误。

如果列表文件中的一个或多个文件包含1个或多个空格或其中一个字符

&()[]{}^=;!'+,`~

在文件名中，必须在列表文件中引用此文件名。

示例：

"file 1.zip";"file A.pdf" fileB.pdf "file C.pdf"
file 2.zip;"file A.pdf" fileB.pdf "file C.pdf" fileD.pdf
file3.zip;fileB.pdf fileD.pdf
file4.zip;"fileA.pdf" fileC.pdf fileE.pdf
file5.zip;file*.pdf
file6.zip;file*.pdf readme.txt

归档文件名也可以没有引号，因为在命令行上使用"%%~a"调用 WinRAR 。

最后两行表明也可以使用带有1个或更多通配符的文件名模式。但是，只有当无法创建ZIP文件时， WinRAR 才会输出错误消息No files to add，因为根本没有找到要添加的文件。因此，如果没有file*.pdf，第5行会生成错误消息，但如果存在至少readme.txt并且可以将第6行添加到存档文件中，则第6行不会生成错误消息。

在 WinRAR 的帮助下，

WinRAR 在退出时根据 WinRAR退出代码列表在退出时设置errorlevel。但是，如果在任何情况下输出错误消息，则评估批处理文件中的退出代码没有多大意义。只有在发生任何错误时，错误日志文件才由 WinRAR 创建。

最后但并非最不重要的是，也可以使用switch -log来获取添加到存档的文件的名称，这些文件写入日志文件，并使用type和{{1}输出这些列表在控制台窗口中。有关切换more的详细信息，请参阅 WinRAR 的帮助。

要了解使用过的控制台命令及其工作方式，请打开命令提示符窗口，执行以下命令，并完全阅读为每个命令显示的所有帮助页面。

-log
cls /?
del /?
echo /?
for /?
if /?
pause /?
rem /?
set /?

如何使用WinRAR创建多个ZIP存档时显示丢失文件列表和其他错误？

2 个答案: