Question

我有两个数据集，一个是合约，一个是市场价格。我想要完成的要点是找到与横截面数据集中的一段时间相对应的时间序列的平均值。请看下面。

示例数据集1：

Beginning Ending    Price
1/1/2014  5/15/2014 $19.50
3/2/2012  10/9/2015 $20.31
...
1/1/2012 1/8/2012 $19.00

在上面的示例中，有几个合同，第一个跨越2014年1月到2014年5月，第二个从2012年3月到2015年10月。每个合同都有一个单一的价格。第二个数据集具有每周市场价格。

示例数据集2：

Date     Price
1/1/2012 $18
1/8/2012 $17.50
....
1/15/2015 $21.00

我想在数据集1的每个合约的开始和结束期间找到平均“市场价格”（即数据集2中的平均价格）。因此，对于2012年1月1日的第三个合同到第1/20/2012，从第二个数据集输出将是（18 + 17.50）/ 2 = 17.75。然后将此值合并回原始数据集。

我使用Stata，但也可以使用R或Excel。

另外，如果您对标题有更好的建议，我会非常感激！

Answer 1

您可以将合约横截面数据与时间序列进行交叉，时间序列形成每个成对组合，从日期范围之外降低价格，并计算平均值，如下所示：

/* Fake Data */
tempfile ts ccs

clear
input str9 d p_daily
"1/1/2012" 18
"1/8/2012" 17.50
"1/15/2015" 21.00 
end
gen date = date(d,"MDY")
format date %td
drop d
rename date d
save `ts'
clear
input id str8 bd str9 ed p_contract
1 "1/1/2014"  "5/15/2014" 19.50
2 "3/2/2012"  "10/9/2015" 20.31
3 "1/1/2012"  "1/8/2012" 19.00
end
foreach var of varlist bd ed {
    gen date = date(`var',"MDY")
    format date %td
    drop `var'
    rename date `var'
}
save `ccs'

/* Calculate Mean Prices and Merge Contracts Back In */
cross using `ts'
sort id d
keep if d >= bd & d <=ed
collapse (mean) mean_p = p_daily, by(id bd ed p_contract)
merge 1:1 id using `ccs', nogen
sort id

这可以让你这样：

  id   p_contract          bd          ed   mean_p  
     1       19.5   01jan2014   15may2014        .  
     2      20.31   02mar2012   09oct2015       21  
     3         19   01jan2012   08jan2012    17.75

合并对应于不同数据集中的时间跨度的时间序列的平均值

1 个答案: