Question

我有一个注册表单，我试图放置一个Html.EditorFor（）。

EG：

@ModelType RegisterViewModel 
    <othermarkup />
<div>
    @Html.LabelFor(Function(m) m.ConfirmPassword, New With {.class = "required"})
    <div>
        @Html.PasswordFor(Function(m) m.ConfirmPassword)
        @Html.ValidationMessageFor(Function(m) m.ConfirmPassword)
    </div>
</div>

<div>
    @Html.EditorFor(Function(m) m.AlertSettings)
</div>
<othermarkup />

RegisterViewModel包含一个名为AlertSettings的属性（类型为AlertSettingsViewModel），AlertSettingsViewModel.vbhtml的编辑器模板如下所示：

@ModelType AlertSettingsViewModel
    <othermarkup />
<div class="panel-heading">Personalized Alert Settings</div>
<div class="panel-body">
    <div class="col-sm-6">
        <div>
            <label for="Disciplines">Disciplines</label>
            @Html.ValidationMessageFor(Function(m) m.Disciplines)
            @Html.CheckBoxListFor(Function(m) m.Disciplines, SelectLists.Disciplines())
        </div>

        <div class="visible-xs"><br /></div>
    </div>
</div>
<othermarkup />

AlertSettingsViewModel的Disciplines属性是一个Integer数组。

我使用自定义HtmlHelper生成复选框列表。这包括以下两种方法（首先调用第二种方法）：

''' <summary>
''' Returns a checkbox for each of the provided <paramref name="items"/>.
''' </summary>
<System.Runtime.CompilerServices.Extension>
Public Function CheckBoxListFor(Of TModel, TValue)(htmlHelper As HtmlHelper(Of TModel), expression As Expression(Of Func(Of TModel, TValue)), items As IEnumerable(Of SelectListItem), Optional htmlAttributes As Object = Nothing) As MvcHtmlString
    Dim listName = ExpressionHelper.GetExpressionText(expression)
    Dim metaData = ModelMetadata.FromLambdaExpression(expression, htmlHelper.ViewData)

    items = GetCheckboxListWithDefaultValues(metaData.Model, items)
    Return htmlHelper.CheckBoxList(listName, items, htmlAttributes)
End Function




''' <summary>
''' Returns a checkbox for each of the provided <paramref name="items"/>.
''' </summary>
<System.Runtime.CompilerServices.Extension>
Public Function CheckBoxList(htmlHelper As HtmlHelper, listName As String, items As IEnumerable(Of SelectListItem), Optional htmlAttributes As Object = Nothing) As MvcHtmlString
    Dim Result As String = ""
    For Each item In items
        Dim div = New TagBuilder("div")
        div.MergeAttributes(New RouteValueDictionary(htmlAttributes), True)
        div.MergeAttribute("class", "checkbox") ' default class

        Dim label = New TagBuilder("label")

        Dim cb = New TagBuilder("input")
        cb.MergeAttribute("type", "checkbox")
        cb.MergeAttribute("name", listName)
        cb.MergeAttribute("value", If(item.Value, item.Text))
        If item.Selected Then
            cb.MergeAttribute("checked", "checked")
        End If

        label.InnerHtml = cb.ToString(TagRenderMode.SelfClosing) & item.Text

        div.InnerHtml = label.ToString()

        Result &= div.ToString()
    Next

    Return New MvcHtmlString(Result)
End Function

我遇到的问题是，当调用编辑器模板时，对ExpressionHelper.GetExpressionText（表达式）的最终调用仅返回直接属性名称（例如＆＃34; Disciplines＆＃34;）而不是全名在上下文中（例如，＆＃34; AlertSettings.Disciplines＆＃34;）。

如何获取全名而不仅仅是直接名称？这是我第一次尝试使用编辑器模板，而且我很难找到这个特定用例的示例。

Answer 1

我能够通过替换：

来纠正这个问题

Dim listName = ExpressionHelper.GetExpressionText(expression)

使用：

Dim listName = htmlHelper.NameFor(expression).ToString

在CheckboxListFor方法中。

希望这对其他人有用。

如何使用编辑器模板中的自定义htmlhelper包含完整的属性名称

1 个答案: