Question

这是我的组件整体结构：

我的组件
- 属性分类：TCollection（属于TCategory）
  - t类别
    - 属性图标：TPicture读取FIcon写入SetIcon;
    - property示例：整数读取FExample write SetExample;
    - （其他类别属性......）
- （其他财产......）

在IDE的Object Inspector中，我选择了一张图片并成功序列化（我在表单视图中将其作为文本进行了检查）。我在SetIcon方法上设置了断点，当我编译并运行应用程序时，它根本没有被调用。与此同时，SetExample被调用正确。

TPicture属性有什么问题？

P.S：在IDE中调用Set方法，但不在运行时调用。

这是代码的MCVE：

unit MCVE;

interface

uses
  System.SysUtils, System.Classes, Vcl.Controls, Graphics, Dialogs;

type
  TMyCollectionItem = class(TCollectionItem)
  private
    FIcon: TPicture;
    procedure SetIcon(const Value: TPicture);
  public
    constructor Create(Collection: TCollection); override;
  published
    property Icon: TPicture read FIcon write SetIcon;
  end;

  TMyCollection = class(TCollection)
  end;

  TMCVE = class(TCustomControl)
  private
    FCollection: TMyCollection;
    procedure SetCollection(const Value: TMyCollection);
  public
    constructor Create(AOwner: TComponent); override;
  published
    property MyCollection: TMyCollection read FCollection write SetCollection;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Samples', [TMCVE]);
end;

{ TMyCollectionItem }

constructor TMyCollectionItem.Create(Collection: TCollection);
begin
  inherited;
  FIcon := TPicture.Create;
end;

procedure TMyCollectionItem.SetIcon(const Value: TPicture);
begin
  ShowMessage('SetIcon is called!');
  FIcon.Assign(Value);
end;

{ TMCVE }

constructor TMCVE.Create(AOwner: TComponent);
begin
  inherited;
  FCollection := TMyCollection.Create(TMyCollectionItem);
end;

procedure TMCVE.SetCollection(const Value: TMyCollection);
begin
  FCollection := Value;
end;

end.

Answer 1

对于Integer，Boolean，Double等简单类型，流媒体按照您描述的方式运行。流框架读取值，并调用属性设置器。

对于像TPicture这样更复杂的类型，它不会发生这种情况。流式传输框架无法调用属性setter。为了做到这一点，需要掌握一个完全形成的TPicture。并且它不知道如何做到这一点，先验。

所以恰恰相反，流式框架调用属性的getter来获取组件构造函数创建的TPicture实例。然后流存储在.dfm文件中的TPicture状态。

碰巧，TPicture没有已发布的属性。图片数据将保存到名为Data的属性下的.dfm文件中。那么，它来自何处。答案是在重写的DefineProperties方法中。代码如下所示：

procedure TPicture.DefineProperties(Filer: TFiler);

  function DoWrite: Boolean;
  begin
    // .... code removed for brevity
  end;

begin
  Filer.DefineBinaryProperty('Data', ReadData, WriteData, DoWrite);
end;

WriteData和ReadData方法执行流式传输。

所以，回顾一下。您问为什么在图片属性中流式传输时未调用TPicture属性的setter。它不会被调用，因为您在构造函数中创建的图片对象在其属性中流动。

创建表单时，不会调用TPicture属性的Set方法

1 个答案: