示例XML输入：

Question

看起来libxslt不支持XSLT 2.0和xsl:result-document。有没有办法使用xsl:result-document或libxslt模仿xsltproc？

Answer 1

是的，有exsl:document。一个简单的例子：

==== foo.xsl ====
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
                xmlns:exsl="http://exslt.org/common"
                extension-element-prefixes="exsl">
  <xsl:output method="html"/>
  <xsl:template match="/">
    <exsl:document href="toc.html" method="html">
      <html>
        <body>
          <xsl:apply-templates select=".//h1"/>
        </body>
      </html>
    </exsl:document>
    <xsl:apply-templates/>
  </xsl:template>
  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

将此作为输入：

==== foo.html ====
<html>
  <body>
    <h1>Hello, world!</h1>
    <p>Some longwinded text follows.</p>
  </body>
</html>

像这样跑：

xsltproc foo.xsl foo.html

将这产生于stdout：

<html>
  <body>
    <h1>Hello, world!</h1>
    <p>Some longwinded text follows.</p>
  </body>
</html>

同时也将此内容写入toc.html：

<html><body><h1>Hello, world!</h1></body></html>

Answer 2

如果libxslt实现了 EXSLT ，那么您可以使用 <exsl:document> 扩展元素。

如果没有，那么你必须编写自己的扩展函数，因为XSLT 1.0不支持创建多个结果文档。

更新：正如this comment中所确认的那样，libxslt实现了EXSLT。只需抓住它并使用 <exsl:document> 。

Answer 3

这是一个示例，演示如何在遍历节点集时使用扩展来创建无限数量的文件。再次，使用xsltproc（libxslt）

示例XML输入：

<clients>
    <client id="ACME1" name="ACME Company 1"/>
    <client id="ACME2" name="ACME Company 2"/>
    <client id="ACME3" name="ACME Company 3"/>
</clients>

示例XSLT：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" 
                xmlns:exsl="http://exslt.org/common"
                extension-element-prefixes="exsl">

<xsl:output method="html" indent="yes" encoding="UTF-8" />

<xsl:template match="/">
    <xsl:for-each select="/clients/client">
    <exsl:document href="{@id}.html" method="html">
      <html>
        <body>
          <h1>Company: <xsl:apply-templates select="@name"/></h1>
        </body>
      </html>
    </exsl:document>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

将生成3个文件ACME1.html，ACME2.html等

libxslt是否具有将文档拆分为多个文档的功能？

3 个答案:

示例XML输入：

示例XSLT：