Question

我写了这个函数来计算数字的回文：

let palindrome n = 
    let mutable current = n
    let mutable result = 0
    while(current > 0) do
        result <- result * 10 + current % 10
        current <- current / 10

    result

如何以更实用的方式重写它？

Answer 1

目前还不清楚自己想做什么。给定的palindrome函数只是反转整数的数字：

> palindrome 1;;
val it : int = 1
> palindrome 12;;
val it : int = 21
> palindrome 123;;
val it : int = 321
> palindrome 9852;;
val it : int = 2589

那些不是palindromic numbers，但让我们将问题分成更小的构建块。

您可以轻松将整数拆分为数字列表。实际上，拆分成 reverse 数字列表是我能想到的最简单的方法：

let rec revdigits i =
    let tens = i / 10
    if tens = 0
    then [i]
    else
        let ones = i % 10
        ones :: revdigits tens

这是int -> int list类型的函数。

示例：

> revdigits 1;;
val it : int list = [1]
> revdigits 12;;
val it : int list = [2; 1]
> revdigits 123;;
val it : int list = [3; 2; 1]
> revdigits 9852;;
val it : int list = [2; 5; 8; 9]

将数字列表连接成数字也很容易：

let rec concat digits =
    match digits with
    | [] -> 0
    | h :: t -> h * int (10. ** float t.Length) + concat t

此函数的类型为int list -> int。

示例：

> concat [1];;
val it : int = 1
> concat [1; 2];;
val it : int = 12
> concat [1; 2; 3];;
val it : int = 123
> concat [2; 5; 8; 9];;
val it : int = 2589

使用这些构建块，您可以轻松编写与palindrome函数相同的函数：

let reverse = revdigits >> concat

此函数的类型为int -> int。

示例：

> reverse 1;;
val it : int = 1
> reverse 12;;
val it : int = 21
> reverse 123;;
val it : int = 321
> reverse 2589;;
val it : int = 9852

奖励：如果你不想反转数字，你可以这样做，但我不认为这个版本是尾递归的：

let rec digits i =
    let tens = i / 10
    if tens = 0
    then [i]
    else
        let ones = i % 10
        digits tens @ [ones]

此函数的类型为int -> int list。

示例：

> digits 1;;
val it : int list = [1]
> digits 12;;
val it : int list = [1; 2]
> digits 123;;
val it : int list = [1; 2; 3]
> digits 9852;;
val it : int list = [9; 8; 5; 2]

Answer 2

你可以使用尾递归函数来完成它。匹配result的值：如果他的值= 0，则返回结果，否则在current和result上进行计算。

let palindrome n =
  let rec rec_palindrome current result = match current with
    | 0 -> result
    | _ -> rec_palindrome (result * 10 + current % 10) (current / 10) 
  rec_palindrome n 0

另外，在我的版本中，这不是可变值。

以更实用的方式重写函数

2 个答案: