Question

我问的是一个新问题，因为How to plot histograms from rows in data file gnuplot中的更新没有受到太多关注。相关问题：gnuplot histogram: How to put values on top of bars和gnuplot rowstacked histogram: how to put sum above bars

t.dat文件如下所示：

目标是计算文件t.dat中四组数字的标准偏差，并将它们显示为组成直方图的条形图上方的标签。第1组：第1-40行第2组：第41-80行第3组：第81-120行第4组：第121-160行

到目前为止，我只是设法手动执行此操作。我已将所需的行范围分成单个文件，i。即tempos1.dat，tempos4.dat，tempos9.dat和tempos16.dat，使用统计数据计算出标准差，并将其显示为标签。

以下是代码：

set term pngcairo
set out 'st-dev.png'
unset key
stats "tempos1.dat" using 1 name "A"
stats "tempos4.dat" using 1 name "B"
stats "tempos9.dat" using 1 name "C"
stats "tempos16.dat" using 1 name "D"
set label "0.6234" at 28,275
set label "0.4666" at 90,90
set label "0.9836" at 149,85
set label "0.2947" at 210,65
set boxwidth 0.9 relative
set style data histogram
set style histogram cluster gap 1
set style fill solid 1.0 border -1
set xrange [0:250]
set xtics ("1" 40, "4" 100, "8" 160, "16" 220)
plot for [i=1:4] 't.dat' using ($0+20+(i-1)*61):1 every ::((i-1)*40)::(i*40-1) with boxes lt i

我阅读了相关帖子，看来，要将std dev放在条形图上方我只需在 using 子句中添加一列，其中包含存储std_dev的变量，但是现在它是通过手动拆分文件计算的。这是所需的输出： enter image description here

我该怎么做？

Answer 1

您可以使用do for对四个块进行迭代，使用您stats命令中已有的using和every设置来调用plot 。然后，在每次迭代中，使用stats给您的许多值设置适当的标签：

STATS_mean_x作为标签的x坐标
STATS_max_y作为y坐标（加上1个字符高度的偏移量，使用set label ... offset 0,1完成）
STATS_stddev_y作为计算的标准差本身：

set term pngcairo
set out 'st-dev.png'
unset key
set boxwidth 0.9 relative
set style fill solid 1.0 border -1
set xlabel "Número de processos"
set ylabel "Tempo de execução (s)"
set xrange [0:250]
set xtics ("1" 40, "4" 100, "8" 160, "16" 220)

do for [i=1:4] {
    stats 't.dat' using ($0+20+(i-1)*61):1 every ::((i-1)*40)::(i*40-1) nooutput
    set label i sprintf('%.4f', STATS_stddev_y) center at STATS_mean_x,STATS_max_y offset 0,1
}

plot for [i=1:4] 't.dat' using ($0+20+(i-1)*61):1 every ::((i-1)*40)::(i*40-1) with boxes lt i

enter image description here

gnuplot rowstacked histogram：如何计算并将标准偏差置于条形图之上？

1 个答案: