Question

我的代码中有这样的内容：

data SomeKind = Kind1 | Kind2 deriving Eq

data SomeValue (t :: SomeKind) = SomeValue

someValue1 :: SomeValue Kind1
someValue1 = SomeValue

someValue2 :: SomeValue Kind2
someValue2 = SomeValue

我希望将类型级别的类型提升到价值级别，或许类似于：

valueKind :: SomeValue a -> SomeKind

将：

valueKind someValue1 == Kind1
valueKind someValue2 == Kind2

有可能吗？

Answer 1

valueKind :: SomeValue a -> SomeKind是不可能的。 a类型参数不以任何形状或形式存在于运行时，因此我们无法对其进行分支。

在运行时和编译时使用类型的标准方法是制作所谓的单例类型。单例由原始类型的类型级版本索引，并具有我们可以通过模式匹配显示索引的属性：

data SSomeKind (i :: SomeKind) where
  SKind1 :: SSomeKind Kind1
  SKind2 :: SSomeKind Kind2

他们被称为单身人士，因为对于每个类型索引，只有一个值。同样，对于每个值，只有一个类型索引选择。这种对应关系允许我们使用SSomeKind作为SomeKind的运行时表示。

valueKind' :: SSomeKind a -> SomeKind
valueKind' SKind1 = Kind1
valueKind' SKind2 = Kind2

创建单例定义和相关的升降功能是一项相当机械的工作。 singletons库自动化并简化它。在我们的案例中：

{-# LANGUAGE TemplateHaskell, DataKinds, GADTs, TypeFamilies, ScopedTypeVariables #-}

import Data.Singletons.TH

$(singletons [d| data SomeKind = Kind1 | Kind2  |])
-- generates a lot of stuff, including the SSomeKind definition.

-- works the same as our previously defined function
valueKind' :: SSomeKind a -> SomeKind
valueKind' = fromSing

-- we can also polymorphically get specific singleton values:
foo :: Sing Kind1
foo = sing -- now foo equals SKind1

图书馆里还有很多东西。有关快速入门和进一步参考，请参阅this page。

Answer 2

如果您可以容忍类型类约束，则可以使用SomeKind中每种类型的实例来完成此操作。这与Kindable类型类

非常相似

class SomeKindable (k :: SomeKind) where
    someKindOf :: p k -> SomeKind

instance SomeKindable Kind1 where
    someKindOf _ = Kind1

instance SomeKindable Kind2 where
    someKindOf _ = Kind2

valueKind ::  SomeKindable a => SomeValue a -> SomeKind
valueKind = someKindOf

编译器无法告知所有k :: SomeKind实例都有SomeKindable k个实例。如果您需要为每个SomeValue提供此功能而无法显示SomeKindable，则可以将该值与SomeKindable中的GADT字典打包在一起。

{-# LANGUAGE GADTs #-}

data SomeValue (t :: SomeKind) where
    SomeValue :: SomeKindable t => SomeValue t

valueKind :: SomeValue a -> SomeKind
valueKind (p@SomeValue) = someKindOf p

Answer 3

您可以定义一个类型类，它根据type-parameter返回相关值。

class ValueKind (t :: SomeKind) where
    valueKind :: f t -> SomeKind

instance ValueKind Kind1 where
    valueKind _ = Kind1

instance ValueKind Kind2 where
    valueKind _ = Kind2

如何将数据类型带入价值水平？

3 个答案: