Question

我正在尝试移动一个物体（矩形用于我们的目的），从A点移动到D.但是，一路上我想要停止不同段的运动并等待一段时间。

例如，我想从A移动到B，等待5秒，然后从B移动到C，等待2秒。最后，从C移到D.

我尝试过几件事。首先，我通过给它一个“速度”（xspeed）并通过xspeed增加它的位置（xpos）来移动我的对象。然后使用if语句，当它达到100时我停止了位置。然后计数5秒并再次开始运动。但是，由于运动开始经过x位置100，因此if语句不允许我向前移动。我不知道我是否可以覆盖这个if语句。以下是我所做的代码：

  class Pipe {
  color c;
  float xpos;
  float ypos;
  float xspeed;
  int time;

  Pipe(color c_, float xpos_, float ypos_, float xspeed_) {
    c = c_;
    xpos = xpos_;
    ypos = ypos_;
    xspeed = xspeed_;
  }

  void display() {
    noStroke();
    fill(c);
    rectMode(CENTER);
    rect(xpos,ypos,10,200);
  }


  void pipeMove() {
    xpos = xpos + xspeed;
    if (xpos > 100) {
      xpos = 100;
      if (millis() > time) {
        time = millis()+5000;
        xpos = xpos + xspeed;
      }
    }
  }
}

Pipe myPipe1;
Pipe myPipe2;

void setup() {
  size(1500,500);
  myPipe1 = new Pipe(color(85,85,85),0,height/2,2);
//  myPipe2 = new Pipe(color(85,85,85),-100,height/2,2);
}

void draw() {
  background(255);
  myPipe1.display();
  myPipe1.pipeMove();
//  myPipe2.display();
//  myPipe2.pipeMove();
}

我尝试的另一个选项是使用noLoop（）停止Processing中的自动循环，并循环我的类中的位置。但是，这不会移动我的对象。请参阅我的for-loop下面的代码。

class Pipe {
  color c;
  float xpos;
  float ypos;
  float xspeed;
  int time;

  Pipe(color c_, float xpos_, float ypos_, float xspeed_) {
    c = c_;
    xpos = xpos_;
    ypos = ypos_;
    xspeed = xspeed_;
  }

  void display() {
    noStroke();
    fill(c);
    rectMode(CENTER);
    rect(xpos,ypos,10,200);
  }


  void pipeMove() {
    for (int i = 0; i<100; i = i+1) {
    xpos = xpos + i;
    }
  }
}

Answer 1

我认为你的第一种方法是正确的。你已经完成了第一部分，现在你只需要添加其他步骤。解决此问题的一种方法可能是在Pipe课程中使用状态。

我的意思是，你只需要跟踪管道当前所处的步骤，然后根据你所处的步骤做正确的事情。最简单的方法可能是在您的Pipe类中添加布尔值：

class Pipe {
  color c;
  float xpos;
  float ypos;
  float xspeed;
  int time;

  boolean movingToA = true;
  boolean waitingAtA = false;
  boolean movingToB = false;
  //...

然后在你的pipeMove()函数中，根据你所处的状态做正确的事情，并改变状态以改变行为：

  void pipeMove() {

    if (movingToA) {

      xpos = xpos + xspeed;

      if (xpos > 100) {
        xpos = 100;
        movingToA = false;
        waitingAtA = true;
        time = millis();
      }
    } else if (waitingAtA) {
      if (millis() > time + 5000) {
        waitingAtA = false;
        movingToB = true;
      }
    } else if (movingToB) {
      xpos = xpos + xspeed;

      if (xpos > 200) {
        xpos = 200;
        movingToB = false;
      }
    }
  }
}

这里有一些非常明显的改进 - 例如，您可以使用枚举值，或潜在操作的数据结构，或参数化行为。但基本原理是相同的：根据您所处的状态执行不同的操作，然后更改该状态以更改行为。

翻译对象，停止和继续 - 处理

1 个答案: