Question

我正在通过使用它来解析HXT文件来学习GPX。一个例子是here。到目前为止，我已经得到了以下内容：

import Data.Time
import Text.XML.HXT.Core

data Gpx    = Gpx [Trk]           deriving (Show)
data Trk    = Trk [TrkSeg]        deriving (Show)
data TrkSeg = TrkSeg [TrkPt]      deriving (Show)
data TrkPt  = TrkPt Double Double deriving (Show)

parseGpx =
  getChildren >>> isElem >>> hasName "gpx" >>>
  getChildren >>> isElem >>> hasName "trk" >>>
  parseGpxTrk >>> arr Gpx

parseGpxTrk = undefined
parseGpxTrkSegs = undefined

您可以看到它不完整，但仍应进行类型检查。不幸的是，我已经遇到了一个错误：

Couldn't match type ‘Trk’ with ‘[Trk]’
Expected type: Trk -> Gpx
  Actual type: [Trk] -> Gpx
In the first argument of ‘arr’, namely ‘Gpx’
In the second argument of ‘(>>>)’, namely ‘arr Gpx’

这个错误说的是我试图将parseGpxTrk箭头中的每个匹配项目传递给arr Gpx构造函数，但我真正想要的是通过传递整个匹配列表arr Gpx构造函数。

那么，我如何通过我的HXT构造函数将arr Gpx（或一般箭头？）传递给列表，而不是传递每个条目通过arr Gpx构造函数列出？

Answer 1

这是一个对我来说非常好的解决方案

{-# LANGUAGE Arrows #-}

import Data.Maybe
import Text.Read
import Text.XML.HXT.Core
import Control.Applicative

data Gpx    = Gpx [Trk]           deriving (Show)
data Trk    = Trk [TrkSeg]        deriving (Show)
data TrkSeg = TrkSeg [TrkPt]      deriving (Show)
data TrkPt  = TrkPt Double Double deriving (Show)

最棘手的可能是parseTrkPt，因为为了做到正确，你必须处理解析String到Double，这可能会失败。我已决定让它返回Maybe TrkPt代替，然后处理下一行：

elemsNamed :: ArrowXml cat => String -> cat XmlTree XmlTree
elemsNamed name = isElem >>> hasName name

parseTrkPt :: ArrowXml cat => cat XmlTree (Maybe TrkPt)
parseTrkPt = elemsNamed "trkpt" >>>
    proc trkpt -> do
        lat <- getAttrValue "lat" -< trkpt
        lon <- getAttrValue "lon" -< trkpt
        returnA -< TrkPt <$> readMaybe lat <*> readMaybe lon

我在这里也使用了proc语法，因为我认为它更清晰。 TrkPt <$> readMaybe lat <*> readMaybe lon的类型为Maybe TrkPt，如果Nothing中的任何一个返回readMaybe，则会返回Nothing。我们现在可以汇总所有成功的结果：

parseTrkSeg :: (ArrowXml cat, ArrowList cat) => cat XmlTree TrkSeg
parseTrkSeg =
    elemsNamed "trkseg" >>>
    (getChildren >>> parseTrkPt >>. catMaybes) >. TrkSeg

括号在这里很重要，我花了一段时间才弄明白这一部分。根据您放置parens的位置，您会得到不同的结果，例如[TrkSeg [TrkPt a b], TrkSeg [TrkPt c d]]而不是[TrkSeg [TrkPt a b, TrkPt c d]]。解析器的下一个遵循类似的模式是直截了当的：

parseTrk :: ArrowXml cat => cat XmlTree Trk
parseTrk =
    elemsNamed "trk" >>>
    (getChildren >>> parseTrkSeg) >. Trk

parseGpx :: ArrowXml cat => cat XmlTree Gpx
parseGpx =
    elemsNamed "gpx" >>>
    (getChildren >>> parseTrk) >. Gpx

然后你可以非常简单地运行它，尽管你仍然必须钻取传递根元素：

main :: IO ()
main = do
    gpxs <- runX $ readDocument [withRemoveWS yes] "ana.gpx"
                >>> getChildren
                >>> parseGpx
    -- Pretty print the document
    forM_ gpxs $ \(Gpx trks) -> do
        putStrLn "GPX:"
        forM_ trks $ \(Trk segs) -> do
            putStrLn "\tTRK:"
            forM_ segs $ \(TrkSeg pts) -> do
                putStrLn "\t\tSEG:"
                forM_ pts $ \pt -> do
                    putStr "\t\t\t"
                    print pt

诀窍是使用ArrowList类型类中的方法，特别是>.类型为a b c -> ([c] -> d) -> a b d的方法。它汇总了ArrowList中的元素，将其传递给将其转换为新类型的函数，然后在该新类型ArrowList上输出新的d。

如果你想要，你甚至可以为最后3个解析器抽象一点：

nestedListParser :: ArrowXml cat => String -> cat XmlTree a -> ([a] -> b) -> cat XmlTree b
nestedListParser name subparser constructor
    =   elemsNamed name
    >>> (getChildren >>> subparser)
    >.  constructor

parseTrkSeg :: (ArrowXml cat, ArrowList cat) => cat XmlTree TrkSeg
parseTrkSeg = nestedListParser "trkseg" (parseTrkPt >>. catMaybes) TrkSeg

parseTrk :: ArrowXml cat => cat XmlTree Trk
parseTrk = nestedListParser "trk" parseTrkSeg Trk

parseGpx :: ArrowXml cat => cat XmlTree Gpx
parseGpx = nestedListParser "gpx" parseTrk Gpx

如果你想完成GPX文件的其余语法，这可能会派上用场。

如何使用数据类型构造函数包装HXT的整个匹配列表？

1 个答案: