Question

在Haskell中，您可以使用Functor自动派生Foldable，Traversable和deriving。但是，无法派生Applicative。考虑到有一种明显的方法来定义Applicative实例（相当于压缩应用程序），是不是有任何方法可以启用deriving Applicative？

Answer 1

不，这根本不明显。比较以下Applicative个实例：

[]
ZipList
Data.Sequence.Seq，其Applicative instance declaration运行到数百行。
IO
(->) r
parsec，attoparsec，regex-applicative中的解析器。

Proxy

pipes

这里几乎没有统一性，大多数情况都不明显。

作为David Young comments，[]和ZipList个实例＆＃34;最终都是两个不同的，同等有效的Applicative个实例。列表类型。＆＃34;

Answer 2

现在DerivingVia已发布（GHC-8.6或更高版本），实际上对于任何确定性数据类型，都可以借助Applicative导出DeriveGeneric！也就是说，任何只有一个变体的数据类型：

data Foo x = Foo x | Fe  -- This is non-deterministic and can't derive Applicative
data Bar x = Bar x x (Bar x) -- This is deterministic and can derive Applicative
data Baz x = Baz (Either Int x) [x] -- This is also ok, since [] and Either Int
                                    -- are both Applicative
data Void x -- This is not ok, since pure would be impossible to define.

要派生Applicative，我们首先需要定义一个用于通过泛型派生的包装器：

{-# LANGUAGE DerivingVia #-}
{-# LANGUAGE DeriveFunctor #-}
{-# LANGUAGE UndecidableInstances #-}
{-# LANGUAGE DeriveGeneric #-}
module Generically1 where

import GHC.Generics

newtype Generically1 f x = Generically1 { generically1 :: f x }

fromg1 :: Generic1 f => Generically1 f a -> Rep1 f a
fromg1 = from1 . generically1

tog1 :: Generic1 f => Rep1 f x -> Generically1 f x
tog1 = Generically1 . to1

instance (Functor f, Generic1 f, Functor (Rep1 f)) 
       => Functor (Generically1 f) where
  fmap f (Generically1 x) = Generically1 $ fmap f x

instance (Functor f, Generic1 f, Applicative (Rep1 f)) 
       => Applicative (Generically1 f) where
  pure = tog1 . pure
  f <*> x = tog1 $ fromg1 f <*> fromg1 x

instance (Functor f, Generic1 f, Monad (Rep1 f)) => Monad (Generically1 f) where
  return = pure
  m >>= f = tog1 $ fromg1 m >>= fromg1 . f

要使用它，我们首先为数据类型派生Generic1，然后通过新的Applicative包装器派生Generically1：

data Foo x = Foo x (Int -> x) (Foo x)
  deriving (Functor, Generic1)
  deriving (Applicative, Monad) via Generically1 Foo

data Bar x = Bar x (IO x)
  deriving (Functor, Generic1)
  deriving (Applicative, Monad) via Generically1 Bar

data Baz f x = Baz (f x) (f x)
  deriving (Show, Functor, Generic1)
  deriving (Applicative, Monad) via Generically1 (Baz f)

如您所见，我们不仅为数据类型派生Applicative，而且还可以派生Monad。

之所以可行，是因为这些数据类型的Applicative表示形式有Monad和Generic1的实例。例如，请参见Product type (:*:)。然而，Sum type (:+:)没有Applicative的实例，这就是为什么我们不能为非确定性类型派生它的原因。

通过在GHCi中写入Generic1，可以看到数据类型的:kind! Rep1 Foo表示形式。以下是上述类型的表示形式的简化版本（不包括元数据）：

type family Simplify x where
  Simplify (M1 i c f) = Simplify f
  Simplify (f :+: g) = Simplify f :+: Simplify g
  Simplify (f :*: g) = Simplify f :*: Simplify g
  Simplify x = x

λ> :kind! Simplify (Rep1 Foo)
Simplify (Rep1 Foo) :: * -> *
= Par1 :*: (Rec1 ((->) Int) :*: Rec1 Foo)

λ> :kind! Simplify (Rep1 Bar)
Simplify (Rep1 Bar) :: * -> *
= Par1 :*: Rec1 IO

λ> :kind! forall f. Simplify (Rep1 (Baz f))
forall f. Simplify (Rep1 (Baz f)) :: k -> *
= forall (f :: k -> *). Rec1 f :*: Rec1 f

为什么没有办法在Haskell中派生Applicative Functors？

2 个答案: