Question

在groovy中，我们可以轻松地从地图创建对象并自动填充相应的字段：

def myAddress = new Address([street:"King's street", number:"1200"])

是否可以从地图更新现有对象而无需重新创建它？有点像...

myAddress.update([zip: "30555050", city: "London"])

Answer 1

您可以使用object."${variable}"访问者执行此操作：

map.each { key, value ->
    object."${key}" = value
}

然后，您可以创建一个方法来执行此操作并将其安装在Object.metaClass上，它将随处可用：

@Canonical
class MapSet {

    String name
    int count

    static def setAttributesFromMap(Object o, Map<String, Object> map) {
        map.each { key, value ->
            o."${key}" = value
        }
    }

    static void main(String[] args) {
        Object.metaClass.update = {
            setAttributesFromMap delegate, it
        }

        def o = new MapSet([
                name: "foo",
                count: 5
        ])

        assert o.name == "foo"
        assert o.count == 5

        o.update([
                name: "bar",
                count: 6
        ])

        assert o.name == "bar"
        assert o.count == 6
    }
}

Answer 2

您可以使用 InvokeHelper 类别和 setProperties 方法，这是一个简短的示例：

import groovy.transform.EqualsAndHashCode
import groovy.transform.ToString
import org.codehaus.groovy.runtime.InvokerHelper

@EqualsAndHashCode
@ToString
class Address {
    String street
    String number
    String city
}

Address mainAddress = new Address(street: 'Test', number: '2B', city: 'London')

use InvokerHelper, {
    mainAddress.setProperties([street: 'Lorem', number: 'Ipsum'])
}

assert mainAddress.street == 'Lorem'
assert mainAddress.number == 'Ipsum'
assert mainAddress.city == 'London'

虽然如果你可以避免可变对象，它对你来说更好。否则你必须考虑线程安全性，不要遇到并发问题。您可以使用前面的示例创建一个需要2个参数的静态方法：现有对象和要更新的属性映射。结果，您将获得包含更新字段的新实例。你也可以让你的班级成为不可变的。

Answer 3

在从Szymon的优秀答案中查找/学习并找到了调用帮助程序的其他方法之后，看来答案可以简化为：

InvokerHelper.setProperties(myAddress, [zip: "30555050", city: "London"])"

这非常接近您的要求

myAddress.update([zip: "30555050", city: "London"])

我将此添加为对他的问题的评论，但是它很简单，我认为它应该是它自己的简要顶级答案。

从地图更新groovy对象字段

3 个答案: