Question

我搜索了很多关于这个主题的论文，但似乎找不到我想要的东西。我是SAS Macro的初学者，希望能在这里得到一些帮助。这就是我想要的：

我有一个包含1200个变量的数据集。我想要一个宏将这1199个变量作为OUTCOME运行，并将逻辑回归的P值存储在数据集中。因变量“性别”也是字符，结果变量也是如此。但我不知道如何将类声明放在宏中。以下是我如何将其作为单个过程运行的示例。

 proc logistic data=Baseline_gender ;
 class gender(ref="Male") / param=ref;
 model N284(event='1')=gender ; 
 ods output ParameterEstimates=ok;
 run;

我的想法是创建ODS输出并删除P值以外的不必要变量，并根据模型中的OUTCOME变量名称将它们合并到一个数据集中：例如

 Variable P-value
 A1       0.005
 A2       0.018
 ..       ....

我尝试使用一些proc宏但我不能让它工作！我真的需要帮助，非常感谢你。

Answer 1

SRSwift可能会出现一些问题（对他的方法不够了解），但这是一种使用宏来实现的方法。

首先，计算数据集中的变量数量。通过从dictionary.columns表中选择表来执行此操作。这将变量的数量放入&sqlobs。现在将字典表中的变量名称读入宏变量var1-var&sqlobs。

%macro logitall;
proc sql;
create table count as
select name from dictionary.columns
where upcase(libname) = 'WORK'
  and upcase(memname) = 'BASELINE_GENDER'
  and upcase(name) ne 'GENDER'
;

select name into :var1 - :var&sqlobs
from dictionary.columns
where upcase(libname) = 'WORK'
  and upcase(memname) = 'BASELINE_GENDER'
  and upcase(name) ne 'GENDER'
;
quit;

然后为每个因变量运行proc logistic，每次输出一个以因变量命名的数据集。

%do I = 1 %to &sqlobs;
  proc logistic data=Baseline_gender ;
    class gender(ref="Male") / param=ref;
    model &&var&I.(event='1')=gender ; 
    ods output ParameterEstimates=&&var&I.;
  run;
%end;

现在将所有输出数据集放在一起，在set语句中使用indsname=创建一个带有数据集名称的新变量。

data allvars;
  format indsname dsname varname $25.; 
  set
  %do I = 1 %to &sqlobs;
    &&var&I.
  %end;
  indsname=dsname;
  varname=dsname;
  keep varname ProbChiSq;
  where variable ne 'Intercept';
run;
%mend logitall;

%logitall;

Answer 2

这是一种无宏的方法。它会提前重组数据并使用SAS的by分组。数据以深层格式存储，其中所有结果变量值都存储在一个新变量中。

创建一些示例数据：

data have;
   input 
        outcome1 
        outcome2 
        outcome3 
        gender $;
   datalines;
1 1 1 Male
0 1 1 Male
1 0 1 Female
0 1 0 Male
1 1 0 Female
0 0 0 Female
;
run;

接下来，使用数组将数据转换为深度格式：

data trans;
    set have;
    /* Create an array of all the outcome variables */
    array o{*} outcome:;
    /* Loop over the outcome variables */
    do i = 1 to dim(o);
        /* Store the variable name for grouping */
        _NAME_ = vname(o[i]);
        /* Store the outcome value in the  */
        outcome = o[i];
        output;
    end;
    keep _NAME_ outcome gender;
run;
proc sort data = trans;
    by _NAME_;
run;

重用您的后勤程序，但附加by声明：

proc logistic data = trans;
    /* Use the grouping variable to select multiple analyses  */
    by _NAME_;
    class gender(ref = "Male");
    /* Use the new variable for the dependant variable */
    model outcome = gender / noint; 
    ods output ParameterEstimates = ok;
run;

Answer 3

这是另一种使用宏的方法。首先定义要在全局变量中用作结果的所有变量，然后编写宏脚本。

%let var = var1 var2 var3 ..... var1199;

%macro log_regression;
  %do i=1 %to %eval(%sysfunc(countc(&var., " "))+1);
    %let outcome_var = %scan(&var, &i);
    %put &outcome_var.;

    proc logistic data = baseline_gender desc;
    class gender (ref = "Male") / param = ref;
    model &outcome_var. = gender;
    ods output ParameterEstimates = ParEst_&outcome_var.;
    run;

    %if %sysfunc(exist(univar_result)) %then %do;
      data univar_result;
      set univar_result ParEst_&outcome_var.;
      run;
    %end;
    %else %do;
      data univar_result;
      set ParEst_&outcome_var.;
      run;
    %end;

  %end;
%mend;

SAS Macro Proc Logistic将P值放入数据集中

3 个答案: