Question

我的Tk应用程序在一个函数中有许多“等待”窗口或暂停，这些函数允许其他背景命令有时间完成它们的工作。问题是在函数中使用“5000之后”将禁用应用程序中的所有按钮。我找到了很多信息，最有帮助的是http://wiki.tcl.tk/808。第一个经验教训是，没有脚本的“之后”将不会处理事件循环，其次是vwaits是嵌套的。

因此，我使用以下简单的“暂停”功能代替“之后”：

proc pause {ms {waitvar WAITVAR}} {
   global $waitvar
   after $ms "set $waitvar 1"
   puts "waiting $ms for $waitvar"
   vwait $waitvar
   puts "pause $ms returned"
}

button .b -text PressMe -command {pause 5000 but[incr i]}; # everyone waits on this
pack .b
after 0 {pause 1000 var1}; pause 3000 var2; # works as expected
after 0 {pause 3000 var3}; pause 1000 var4; # both return after 3 secs

我的按钮总是响应，但如果按下，所有其他vwaits都会被保持至少5秒钟。并且在5秒钟内第二次按下也会延迟第一次按下。了解vwaits是嵌套的，现在这是预期的，并没有真正的问题。

这似乎是一个非常简单的解决方案，所以我想就我可能没有的问题发表评论。

Answer 1

您已经列出了主要问题，vwait来电将在另一个vwait电话中快乐地嵌套。（它们是使用对事件循环引擎的递归调用来实现的，所以这是预期的。）当你得到最终嵌套在自身内部的东西时，这可能是一个特殊的问题;你可以很容易地以这种方式炸毁堆栈。解决此问题的传统方法是仔细联锁，例如在处理vwait时禁用调用此特定回调的按钮;这也提供了一个很好的方式来向用户表明你很忙。

另一种方法（你可能仍然使用按钮禁用）是分解代码，而不是：

proc callback {} {
    puts "do some stuff 1"
    pause 5000
    puts "do some stuff 2"
}

你改为：

proc callback {} {
    puts "do some stuff 1"
    after 5000 callback2
}
proc callback2 {} {
    puts "do some stuff 2"
}

这样可以避免vwait本身。它被称为延续传递式编程，在高质量的Tcl代码中很常见。它确实有点棘手。考虑这个循环版本：

proc callback {} {
    for {set i 1} {$i <= 5} {incr i} {
        puts "This is iteration $i"
        pause 1000
    }
    puts "all done"
}

在延续传递方式中，您可以执行以下操作：

proc callback {{i 1}} {
    if {$i <= 5} {
        puts "This is iteration $i"
        after 1000 [list callback [incr i]]
    } else {
        puts "all done"
    }
}

你所拥有的本地状态越多，转换代码就越棘手！

使用Tcl / Tk 8.6，您将获得一些额外的技术。

首先，您可以使用coroutine来简化那些棘手的延续传递内容。

proc callback {} {
    coroutine c[incr ::coroutines] apply {{} {
        for {set i 1} {$i <= 5} {incr i} {
            puts "This is iteration $i"
            after 1000 [info coroutine]
            yield
        }
        puts "all done"
    }}
}

这有点长，但随着状态的大小和复杂性的增加，很多更容易。

另一个新的8.6工具是tk busy命令，它可用于创建方便的模态对话框，在某些操作发生时你无法与之交互（通过具有不可见窗口的巧妙技巧）。这仍然取决于你的代码，以确保用户被告知事情正忙，再次通过标记禁用事件等，但tk busy可以使它更容易实现（并且可以帮助避免一点点棘手问题grab）。

Tck在命令，vwait和事件循环之后

1 个答案: