Question

我有一个时间表可以在表格中显示。

以下是我当前解决方案的示例：

import Graphics.UI.Gtk
import Control.Monad.IO.Class

main = do
  initGUI
  window <- windowNew
  view <- treeViewNew
  store <- listStoreNew initialData
  treeViewSetModel view store
  containerAdd window view
  prepareCols view store
  window `on` deleteEvent $ liftIO mainQuit >> return False
  widgetShowAll window
  mainGUI

initialData :: [[String]]
initialData = [["foo", "bar"], ["baz", "42"]]

prepareCols :: TreeView -> ListStore [String] -> IO ()
prepareCols view store = do
  size <- listStoreGetSize store
  mapM_ (addColumn view store) [0..size-1]

addColumn :: TreeView -> ListStore [String] -> Int -> IO ()
addColumn view store i = addTextColumn view store (!! i) $ show i

addTextColumn :: (TreeViewClass view
                 , TreeModelClass (model row)
                 , TypedTreeModelClass model
                 )
                => view -> model row -> (row -> String) -> String -> IO ()
addTextColumn view model f name = do
  col <- treeViewColumnNew
  rend <- cellRendererTextNew
  treeViewColumnSetTitle col name
  treeViewColumnPackStart col rend True
  cellLayoutSetAttributes col rend model (\row -> [ cellText := f row ])
  treeViewColumnSetExpand col True
  treeViewAppendColumn view col
  return ()

现在我想让每个单元格都可以右键单击，但gtk2hs只提供激活行，没有激活哪个单元格的信息，或者使列标题可单击。

对于一个响应具有信息的点击事件的表，关于哪个行和列被点击（对于列，数字索引是完美的，所以我可以使用此索引来修改），这将是什么方式进入gtk2hs我开始使用的列表），没有诉诸讨厌的事情，比如使用Table并在运行时删除/添加标签。

我使用gtk2hs（gtk3）版本0.12.5.6

Answer 1

您可以采用中描述的解决方案 this Python answer

buttonPressEvent回调可以安装在prepareCols函数中，用于检查事件是否为鼠标右键单击，然后将事件坐标解码为TreeStore路径：

onPathRightClick :: (TreeViewClass view) 
                 => view
                 -> (TreePath -> Int -> IO ()) 
                 -> IO (ConnectId view)
onPathRightClick view callback =
    on view buttonReleaseEvent $ (return False <*) $ runMaybeT $ do
        RightButton <- lift eventButton
        (x, y) <- lift eventCoordinates
        let x' = round x
            y' = round y
        (path, col, _cellpoint) <- MaybeT . liftIO $ treeViewGetPathAtPos view (x', y')
        colIdx <- MaybeT . liftIO $ findIndex (== col) <$> treeViewGetColumns view
        liftIO $ callback path colIdx

prepareCols :: TreeView -> ListStore [String] -> IO ()
prepareCols view store = do
    size <- listStoreGetSize store
    mapM_ (addColumn view store) [0..size-1]
    void $ onPathRightClick view $ \path col -> do
        putStrLn . unwords $ [ "Column:" , show col]
        putStrLn . unwords $ [ "Path:" , show path]

表格基于每个单元格对点击事件做出反应

1 个答案: