Question

#!/usr/bin/perl -w

use strict;

use FileHandle;
use LWP::UserAgent;
use HTTP::Request;

sub printFile($) {

  my $fileHandle = $_[0];

  while (<$fileHandle>) {
    my $line = $_;
    chomp($line);
    print "$line\n";
  }
}

my $message = new FileHandle;

open $message, '<', 'Request.xml' or die "Could not open file\n";
printFile($message);

my $url = qq{https://host:8444};

my $ua = new LWP::UserAgent(ssl_opts => { verify_hostname => 0 });

$ua->proxy('http', 'proxy:8080');
$ua->no_proxy('localhost');

my $req = new HTTP::Request(POST => $url);
$req->header('Host' => "host:8444");
$req->content_type("application/xml; charset=utf-8");
$req->content($message);
$req->authorization_basic('TransportUser', 'TransportUser');

my $response = $ua->request($req);
my $content  = $response->decoded_content();
print $content;

我收到以下错误。

我想使用LWP::UserAgent提交帖子请求，我想将XML文件的位置作为正文。我收到无效的请求正文错误。请求正文无效

Answer 1

我不明白printFile的用途，但您传递文件句柄 $message作为邮件正文，而不是文件的内容。

请注意以下内容

始终 use warnings而不是-w评论专栏
从不使用子程序原型。 sub printFile($)应该只是sub printFile
use FileHandle无需使用文件
文件open失败的原因位于$!。您应始终将其包含在die字符串
切勿使用间接对象表示法。 new LWP::UserAgent应为LWP::UserAgent->new

此版本的代码可能会更好一些，但我无法测试它

#!/usr/bin/perl

use strict;
use warnings;

use LWP;

my $message = do {
  open my $fh, '<', 'Request.xml' or die "Could not open file: $!";
  local $/;
  <$fh>;
};

my $url = 'https://host:8444';

my $ua = LWP::UserAgent->new(ssl_opts => { verify_hostname => 0 });

$ua->proxy(qw/ http proxy:8080 /);
$ua->no_proxy('localhost');

my $req = HTTP::Request->new(POST => $url);
$req->header(Host => 'host:8444');
$req->content_type('application/xml; charset=utf-8');
$req->content($message);
$req->authorization_basic('TransportUser', 'TransportUser');

my $response = $ua->request($req);
my $content  = $response->decoded_content;
print $content;

使用LWP :: UserAgent提交HTTP POST请求，将XML文件内容作为正文

1 个答案: