Question

我有一个TObjectList，我试图写入磁盘。虽然我最终得到一个文件（54个字节），当我将FNAME属性值更改为非常长的时候，文件的大小永远不会改变，当我尝试读取它时我得到nil。我不知道出了什么问题。很抱歉有很长的代码段。很容易理解发生了什么，只是我无法弄清楚为什么它没有做我想要的。

type
  { Declare a new object type. }
  TNewObject = class(TComponent)
  private
    FName: String;
  public
    property BizName: String read FName write FName;
    constructor Create(const AName: String);
    destructor Destroy(); override;
  end;

为我的TObjectList

声明一个全局变量

var
  Form1: TForm1;
  List: TObjectList<TNewObject>;

声明我的构造函数和析构函数..

constructor TNewObject.Create(const AName: String);
begin
  FName := AName;            
end;

destructor TNewObject.Destroy;
begin      
  inherited;
end;

现在添加一个按钮来创建我的对象......

procedure TForm1.CreateButtonClick(Sender: TObject);  
    var     
      Obj: TNewObject;
    begin
      { Create a new List. }
      { The OwnsObjects property is set by default to true -- the list will free the owned objects automatically. }
      List := TObjectList<TNewObject>.Create();

      { Add some items to the List. }
      List.Add(TNewObject.Create('One'));
      List.Add(TNewObject.Create('Two'));

      { Add a new item, but keep the reference. }
      Obj := TNewObject.Create('Three');
      List.Add(Obj);
end;

现在添加一个SAVE按钮

procedure TForm1.SaveButtonClick(Sender: TObject);
var
  i: Integer;
  fs: TfileStream;
begin
  if SaveDialog1.Execute then
  begin
    fs := TfileStream.Create(SaveDialog1.FileName, fmCreate);
    try
      for i := 0 to List.Count - 1 do
      begin

        ShowMessage(List[i].BizName);
        fs.WriteComponent(TNewObject(List[i]));            
      end;
    finally
      fs.Free;
    end;
  end;
end;

CAVEATS：我知道只保存PUBLIC属性......应该是BIZNAME。保存时，3个条目会显示在SHOWMESSAGE中....

我确实记得我的班级注册。

Initialization
RegisterClass(TNewObject);

为了完整起见，这里也是我的Load Routine ......

procedure TForm1.LoadButtonClick(Sender: TObject);
var
  i: Integer;
  fs: TfileStream;
  vRecord: TNewObject;
begin
  if OpenDialog1.Execute then
  begin
    List.Clear; // clear list
    fs := TfileStream.Create(OpenDialog1.FileName, fmopenRead);
    try

      while fs.Position < fs.size do
      begin
        vRecord := TNewObject(fs.ReadComponent(nil));
        ShowMessage(vRecord.FName);           
        List.Add(vRecord);
      end;
    finally
      fs.Free;
    end;
    ShowMessage(IntToStr(List.Count));
  end;
end;

感谢您的帮助。

Answer 1

组件流媒体系统只流发布的属性，需要发布＆＃39; BizName＆＃39;。

或者，您可以覆盖DefineProperties以确定要传输的内容。

type
  TNewObject = class(TComponent)
  private
    FName: String;
    procedure ReadName(Reader: TReader);
    procedure WriteName(Writer: TWriter);
  protected
    procedure DefineProperties(Filer: TFiler); override;
  public
    property BizName: String read FName write FName;
    ...

procedure TNewObject.ReadName(Reader: TReader);
begin
  FName := Reader.ReadString;
end;

procedure TNewObject.WriteName(Writer: TWriter);
begin
  Writer.WriteString(FName);
end;

procedure TNewObject.DefineProperties(Filer: TFiler);
begin
  inherited;
  Filer.DefineProperty('bizname', ReadName, WriteName, FName <> '');
end;

Delphi - 无法将TObjectList保存/加载到FileStream

1 个答案: