如果用户在许可证页面NSIS上单击取消，则显示完成页面

Question

我有两个许可页面，在第二个许可页面中，如果用户选择不安装第三方应用程序，它将显示完成页面。到目前为止，我使用MUI_CUSTOMFUNCTION_ABORT onUserAbort进入完成页面。

但问题是当用户单击“跳过”按钮（它实际上是“取消”按钮并将其重命名为“跳过”）时，它将保留在许可页面上，“安装”按钮将更改为“下一步”按钮（图像1 - ＆gt;图像2 - ＆gt;图3）。我知道这是因为我在Abort中致电onUserAbort。如果我不打电话Abort，那么当用户点击跳过时，该窗口将自动关闭。

您是否知道如何直接转到完成页面？ （图像1 - ＆gt;图像3，没有图像2）

!insertmacro MUI_PAGE_WELCOME
page custom CheckHWSpecs ShowNotMeetRequirementDialog
!insertmacro MUI_PAGE_LICENSE "${SOURCEFOLDER}\license1.txt"
!define MUI_DIRECTORYPAGE_VERIFYONLEAVE
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_STARTMENU Application $StartMenuGroup
!insertmacro MUI_PAGE_INSTFILES
!define MUI_LICENSEPAGE_CHECKBOX
!define MUI_PAGE_CUSTOMFUNCTION_PRE Lic2Pre
!define MUI_PAGE_CUSTOMFUNCTION_SHOW Lic2Show
!insertmacro MUI_PAGE_LICENSE "${SOURCEFOLDER}\license2.txt"
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH
!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES

!define MUI_CUSTOMFUNCTION_ABORT onUserAbort
!insertmacro MUI_LANGUAGE English

Lic2Pre上的代码：

Function Lic2Pre
    StrCpy $R8 2
FunctionEnd

Lic2Show上的代码：

Function Lic2Show
    GetDlgItem $0 $hwndparent 2
    SendMessage $0 ${WM_SETTEXT} 0 "STR:Skip"

    !insertmacro SelectSection ${SEC0013}
    !insertmacro UnselectSection ${SEC0000}
    !insertmacro UnselectSection ${SEC0002}
    !insertmacro UnselectSection ${SEC0003}
    !insertmacro UnselectSection ${SEC0004}
    !insertmacro UnselectSection ${SEC0005}
    !insertmacro UnselectSection ${SEC0007}
    !insertmacro UnselectSection ${SEC0010}
    !insertmacro UnselectSection ${SEC0011}
    !insertmacro UnselectSection ${SEC0012}
FunctionEnd

进入特定页面的代码：

Function RelGotoPage
  IntCmp $R9 0 0 Move Move
    StrCmp $R9 "X" 0 Move
      StrCpy $R9 "120"

  Move:
  SendMessage $HWNDPARENT "0x408" "$R9" ""
FunctionEnd

用户中止的自定义函数：

Function onUserAbort
  StrCmp $R8 2 0 End
    StrCpy $R9 2
    Call RelGotoPage
    Abort
  End:
FunctionEnd

Answer 1

!include Sections.nsh
!include WinMessages.nsh
ShowInstDetails show
!define MUI_CUSTOMFUNCTION_ABORT onUserAbort
!include MUI2.nsh
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_LICENSE "${NSISDIR}\Examples\example1.nsi"
!insertmacro MUI_PAGE_INSTFILES
!define MUI_LICENSEPAGE_CHECKBOX
!define MUI_LICENSEPAGE_CHECKBOX_TEXT "Blah blah blah app and agree..."
!define MUI_PAGE_CUSTOMFUNCTION_SHOW Lic2Show
!define MUI_PAGE_CUSTOMFUNCTION_LEAVE Lic2Leave
!insertmacro MUI_PAGE_LICENSE "${NSISDIR}\Examples\example2.nsi"
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH
!insertmacro MUI_LANGUAGE English

Section /o "Bonus app" SID_BONUS
DetailPrint "Installing bonus app..."
Sleep 2222
SectionEnd

Section "Main app" SID_MAIN
DetailPrint "Installing main app..."
Sleep 2222
SectionEnd

var installBonus
Function Lic2Show
StrCpy $installBonus 1
GetDlgItem $0 $hwndparent 2
SendMessage $0 ${WM_SETTEXT} 0 "STR:&Skip"
!insertmacro UnselectSection ${SID_MAIN} ; Already installed, uncheck
FunctionEnd

Function Lic2Leave
${If} $installBonus == 1
    !insertmacro SelectSection ${SID_BONUS}
${EndIf}
FunctionEnd

Function onUserAbort
${If} $installBonus == 1
    StrCpy $installBonus 0
    System::Call 'USER32::PostMessage(i$HWNDPARENT,i0x408,i 1,i0)' ; Delayed skip 1 page
    Abort
${EndIf}
FunctionEnd

Answer 2

查看Wiki上的Go to a NSIS page