GTK + Forth回调

时间:2014-10-25 00:06:14

标签: callback gtk signals forth

我最近在四年前发现了Manfred Mahlow的一篇文章,该文章接近解决了我遇到的问题。文章“使用Glade在Forth中创建GTK +应用程序”触及了信号处理程序,声明Forth无法使用,只有C才能创建它们。我认为我的问题仍然很小,但我很难过,我非常感谢任何建议。其次,如果有人知道如何在地址中使用短划线向Mahlow先生发送电子邮件,我很乐意听到。

我正在使用Linux版SwiftForth编写一个应用程序来创建自定义窗口并接收按键并写入该窗口。我的目标是实现Charles Moore的colorForth,增强且更加用户友好。我决定使用GTK+,对它知之甚少,但我已经成功但是对于回调(信号处理程序)。整个过程中只有两页代码,所以我把它放在这里:

\ ------------------------ COLOR FORTH -----------------------

ANEW TASK-COLORFORTH

LIBRARY  /usr/lib/i386-linux-gnu/libgtk-3.so.0.1000.8

FUNCTION: gtk_window_new ( code -- addr )
FUNCTION: gtk_widget_destroy ( wptr -- )
FUNCTION: gtk_window_close ( wptr -- )
FUNCTION: gtk_widget_show  ( wptr -- )
FUNCTION: gtk_init  ( -- )
FUNCTION: gtk_window_set_decorated ( wptr flag -- )
FUNCTION: gtk_window_move  ( wptr x y -- )
\ FUNCTION: gtk_widget_new  ( n addr -- )  ( try 0 0 )
\ FUNCTION: gtk_widget_map  ( wptr -- )
\ FUNCTION: gtk_widget_show_all  ( wptr -- )
FUNCTION: gtk_window_get_screen  ( wptr -- wgptr )
\ FUNCTION: gtk_window_present  ( wptr -- )
FUNCTION: gtk_window_set_title ( wptr TitlePtr -- )
FUNCTION: gtk_window_resize ( wptr width height -- )
FUNCTION: gtk_widget_modify_bg ( wptr state cptr -- )
\ FUNCTION: gtk_widget_modify_fg ( wptr state cptr -- )
FUNCTION: gtk_widget_modify_text ( wptr state cptr -- )
FUNCTION: gtk_widget_modify_base ( wptr statre cptr -- )
FUNCTION: g_signal_connect_data ( wptr name callback data 0 0 -- )
FUNCTION: gtk_main ( -- )
FUNCTION: gtk_main_quit ( -- )
FUNCTION: gtk_widget_set_events ( wptr flag -- )

LIBRARY  /usr/lib/i386-linux-gnu/libgdk-3.so.0.1000.8
FUNCTION: gdk_event_get_keyval ( eptr kptr -- )
FUNCTION: gdk_event_get_state ( eptr sptr -- )
FUNCTION: gdk_event_get_event_type ( eptr -- type ) ( requires GET.RETURN )

\ LIBRARY  /usr/lib/i386-linux-gnu/libgio-2.0.so.0.4000.0
\ LIBRARY /lib/i386-linux-gnu/libglib-2.0.so.0.4000.0
\ LIBRARY /usr/lib/i386-linux-gnu/libpango-1.0.so.0.3600.3
\ LIBRARY /usr/lib/i386-linux-gnu/libatk-1.0.so.0.21009.1
\ LIBRARY /usr/lib/i386-linux-gnu/libgobject-2.0.so.0.4000.0
\ LIBRARY /usr/lib/i386-linux-gnu/libgdk_pixbuf-2.0.so.0.3000.7

VARIABLE Window-Ptr
VARIABLE Event-Ptr
VARIABLE KeyVal
VARIABLE KeyState

Z" ColorForth"         VALUE Title
Z" key_press_event"    VALUE Keypress-Name
Z" delete_event"       VALUE Delete-Event-Name
Z" destroy"            VALUE Destroy-Name

CREATE Background 0 , 0 H, 0 H, $2000 H,
CREATE Black 0 , 0 H, 0 H, 0 H,
CREATE White 0 , $E000 H, $E000 H, $8000 H,

\ ----------------------------------------------------------------

ICODE LEAVE.FALSE
    EAX EAX SUB
    RET
END-CODE

ICODE GET.RETURN
    4 # EBP SUB
    EBX 0 [EBP] MOV
    EAX EBX MOV
    RET
END-CODE

         \  This may be the part where I am having problems

: SHUTDOWN
    Window-Ptr @   DUP  gtk_window_close
    gtk_widget_destroy
;

: CB.DELETE.EVENT ( wptr data -- false to destroy )
    RDROP RDROP             ( assuming 2 paramaters on Rstack and return -1 )
    LEAVE.FALSE
;

: CB.DESTROY     ( wptr data -- )
    RDROP RDROP                        ( two parameters here )
    gtk_main_quit
;

: CB.KEYPRESS   ( wptr eptr data -- )     ( assuming 3 parameters on Rstack )
    Window-Ptr @ .  R> . R> . R> .   R@   (  This for diagnosis – eventually )
    SHUTDOWN                              ( goes to a [SWITCH )
;

: STARTUP   ( -- )
    Window-Ptr OFF  Event-Ptr OFF
    gtk_init
    0 gtk_window_new ?DUP    ( 0 = GTK_WINDOW_TOPLEVEL )
      IF DUP Window-Ptr !
         DUP 1024 gtk_widget_set_events       ( 1024 for Keypress signals )
         DUP Title gtk_window_set_title
         DUP 1280 850 gtk_window_resize
         DUP 0 gtk_window_set_decorated
         DUP 0 Background gtk_widget_modify_bg
         DUP Delete-Event-Name  [ ' CB.DELETE.EVENT +ORIGIN ] LITERAL  0
           0 0  g_signal_connect_data
         DUP Destroy-Name  [ ' CB.DESTROY +ORIGIN ] LITERAL 0
           0 0  g_signal_connect_data
         DUP Keypress-Name  [ ' CB.KEYPRESS +ORIGIN ] LITERAL 0
           0 0  g_signal_connect_data
         gtk_widget_show
      THEN
      gtk_main
;

我无法使用通常的g_signal_connect,因为我无法在任何库中找到它。如果它出现了,我会使用它,因为代码更简单。但是,上面的代码编译,当我输入STARTUP时,它就是这样做的。窗口在我指定的位置,信号已设置,但按任意键会使SwiftForth崩溃并出现“分段故障”。

如您所见,我将处理程序的绝对地址提供给信号连接功能。我也尝试将该地址放入变量并将其作为指针处理,但这会产生GTK +错误。

在编写处理程序时,我认为它可以像任何库调用一样运行。输入参数将在返回堆栈上,由GTK在处理程序代码执行时提供,我应该将任何返回放入EAX。但这种分析可能是错误的。我可能正在准备地址错误或处理程序的参数错误,或者完全错误的概念。

我希望,尽管声明处理程序必须在C中,但有一些方法可以在必要时用汇编程序模拟C代码的作用。

我觉得我距离实现这一突破只有一步之遥,如果有人能提出一些建议或地点,我会非常感激。

1 个答案:

答案 0 :(得分:3)

FUNCTION: g_signal_connect_data ( wptr name callback data 0 0 -- ) 我看到你正在使用像' CB.DELETE.EVENT +ORIGIN这样的东西来传递 回调参数。

你不应该开始使用Forth回调吗?您的 CB.DELETE.EVENT(和其他人)需要并期待一个Forth 上下文。

在SwiftForth中,这可以通过

来实现
' CB.DELETE.EVENT 2 CB: *CB.DELETE>EVENT

*CB.DELETE>EVENT作为回调参数传递给g_signal_connect_data

CB:创建一个围绕CB.DELETE.EVENT的包装器,它建立一个 要运行的临时Forth环境。请参阅SwiftForth手册 用于访问给回调的参数。当然了 其他回调也应该适用。

注意:SwiftForth以特定方式处理输入。其他 Forth系统在处理回调输入方面有所不同 参数。但总的来说,不要盲目依赖是件好事 返回堆栈。请务必查看Forth文档。

虽然导入库单词有助于非Forth函数 在Forth环境中运行,相反,运行Forth的话 一个外来语境,用回调词完成。他们允许 用于信号处理程序,完成处理程序,异常处理程序, 为POSIX线程启动例程,Objective-C的方法实现 很多Forth系统在OS下运行 SwiftForth,VFX,iForth,MacForth,iMops和Gforth提供各种方式 创建Forth回调。所以任何索赔都不能在这里使用 我猜是被驳斥了。请参阅this Forth + GTK example

BTW,我在SwiftForth OS X中运行了改编的代码。好的; - )