Question

在我们的项目中，我们要求在连接到CPU的扩展显示器中显示仪表板（Windows窗体）。

目前，我们可以在扩展显示中显示仪表板，但是一旦系统（主要）被锁定，扩展显示器就不会显示任何内容。

我们不允许对工作站锁定进行任何更改。

即使主要设备被锁定，我们也必须在扩展显示器上显示仪表板。一旦仪表板被发送到扩展显示器，有没有删除对主要的依赖？

我们正在使用VS2013和C＃。

谢谢， Srikk

Answer 1

＆＃34;我们不允许对工作站锁定进行任何更改。＆＃34;

非常确定这是一个windows的东西，如果没有＆＃34;对工作站锁定进行更改，就无法绕过它。＆＃34;为了扩展这一点，Windows会在您锁定计算机时锁定所有显示 - 原因很明显。锁定计算机并仍然显示桌面/文件是没有意义的。除非你实际上没有锁定＆＃34;在计算机上，辅助显示器将被Windows锁定（假设这是您正在使用的操作系统）。

为了扩展这一点，可能无法实际锁定计算机，但可以创建一个全局键/鼠标钩（不要忘记你还需要额外的长度来锁定 CTRL + ALT + DELETE 如果你想做的话）忽略所有按键/鼠标移动。

我没有用C＃编写代码，但是我写的AutoIt代码锁定了我的键盘和鼠标，并在我的屏幕上显示飞行的nyan猫。如果有人按下某个键，它会通过Windows API锁定计算机（实际路径）。

;///////////////////////////////
;// Lock Code Created by DT   //
;///////////////////////////////
#include <WinApi.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Sleep(5000);

;///////////////////////////////////////////////////////////////
;// Hook User32.dll to block Mouse/Keyboard Input and Monitor //
;///////////////////////////////////////////////////////////////
Global $stub_KeyProc = DllCallbackRegister("_KeyProc", "int", "int;ptr;ptr")
Global $stub_MouseProc = DllCallBackRegister("_MouseProc", "int", "int;ptr;ptr")
Global $keyboardHook = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($stub_KeyProc), _WinAPI_GetModuleHandle(0), 0)
Global $mouseHook = _WinAPI_SetWindowsHookEx($WH_MOUSE_LL, DllCallbackGetPtr($stub_MouseProc), _WinAPI_GetModuleHandle(0), 0)

;//////////////////////
;// Global Variables //
;//////////////////////
Global $lock = False                                    ;If a key is pressed, set this to True and handle it in our while loop (gets messy otherwise)
Global $desktopSize = WinGetPos("Program Manager")      ;Get the desktop size from Program Manager
Global $maxX = $desktopSize[2]; - 600                   ;Set a Max X Position by using the width of our image and width of desktop
Global $maxY = $desktopSize[3]; - 255                   ;Set a Max Y position by using the height of our image and the height of desktop
Global $splashX = Int(Random(1, $maxX-1))               ;Display our splash randomly in the acceptable space
Global $splashY = Int(Random(1, $maxY-1))               ;Display our splash randomly in the acceptable space
Global $splashXVel = Int(Random(10,20))                 ;Setup a random velocity for our image
Global $splashYVel = 0;Int(Random(-5,5))                ;Setup a random velocity for our image (No need for Y Velocity anymore)

;////////////////////////////
;// Create and Display GUI //
;////////////////////////////
$Form1 = GuiCreate("Locked",400,280,$splashX, $splashY, $WS_POPUP, $WS_EX_LAYERED)              ;Create a GUI Window (Layered For Transparency)
$gifTest = ObjCreate("Shell.Explorer.2")                                                        ;Create a Shell.Explorer Object to display a GIF
$gifTest_ctrol = GuiCtrlCreateObj($gifTest,-5,-5,410,290)                                       ;Push it slightly out of our GUI bounds to hide the border
;                                                                                               ;Create a variable to hold some simple HTML code that displays a GIF
$URL = "about:<html><body bgcolor='#dedede' scroll='no'><img src='C:\Users\DT\Pictures\nyan-cat.gif'></img></body></html>"
$gifTest.Navigate($URL)                                                                         ;Point our shell explorer to our HTML code
_WinAPI_SetLayeredWindowAttributes($Form1, 0xdedede, 255)                                       ;Set our transparency color to our html background to make everything transparent
GUISetState(@SW_SHOW)                                                                           ;And finally, display our GUI

;///////////////////////////////////////////////////////
;// Function that is called whenever a key is pressed //
;///////////////////////////////////////////////////////
Func _KeyProc($nCode, $wParam, $lParam)                                                         ;Grab parameters from our DLL Hook
   If $nCode < 0 Then Return _WinAPI_CallNextHookEx($keyboardHook, $nCode, $wParam, $lParam)    ;If it's not actually a key being pressed call the next hook
   $lock = True                                                                                 ;Otherwise, it's time to lock the computer
   Return 1                                                                                     ;Don't call the next hook (supress key press)
EndFunc

;///////////////////////////////////////////////////////
;// Function that is called whenever the mouse moves  //
;///////////////////////////////////////////////////////
Func _MouseProc($nCode, $wParam, $lParam)                           ;Grab parameters from our DLL Hook
   randomizeVelocity()                                              ;randomize our splash velocity
   randomizePosition()                                              ;and randomize its position
   Return 1                                                         ;then supress the mouse movement
EndFunc

;///////////////////////////////////////////////////////////////////////
;// Simple randomize functions to reuse code and for ease of reading  //
;///////////////////////////////////////////////////////////////////////
Func randomizeVelocity()
   $splashXVel = Int(Random(10,20))
   ;$splashYVel = Int(Random(-3,3))
EndFunc
Func randomizePosition()
   $splashX = Int(Random(1, $maxX-1))
   $splashY = Int(Random(1, $maxY-1))
EndFunc

;/////////////////////////////////////////////////
;// Our program loop (main function basically)  //
;/////////////////////////////////////////////////
hideTaskbar();
While 1                                                             ;loop indefinitely (until we exit :))
   $splashX = $splashX + $splashXVel                                ;Modify splash x position by velocity
   $splashY = $splashY + $splashYVel                                ;Modify splash y position by velocity
   WinMove($Form1,"" , $splashX, $splashY)                          ;and move the window

   ;If $splashX >= $maxX Or $splashX <= 0 Then $splashXVel *= -1        ;if our splash image hits an edge
   ;If $splashY >= $maxY Or $splashY <= 0 Then $splashYVel *= -1        ;reverse its velocity (can be buggy! ;))
   If $splashX >= $maxX Then
      $splashY = Int(Random(1,$maxY-400))
      $splashX = -400;
   EndIf      

   If $lock Then                                                    ;If we have a message to lock the computer
      DllCallbackFree($stub_KeyProc)                                ;release our hooks
      DllCallbackFree($stub_MouseProc)
      _WinAPI_UnhookWindowsHookEx($keyboardHook)
      _WinAPI_UnhookWindowsHookEx($mouseHook)
      showTaskbar();
      Run("rundll32.exe user32.dll,LockWorkStation")                ;and lock the computer
      Exit                                                          ;then exit the program :)
   EndIf
   Sleep(40)
WEnd
;/////////////////////////////////////////////////

Func hideTaskbar()
   WinSetTrans("[Class:Shell_TrayWnd]", "", 0)
   ControlHide('','', WinGetHandle("[CLASS:Button]"))
EndFunc
Func showTaskbar()
   WinSetTrans("[Class:Shell_TrayWnd]", "", 255)
   ControlShow('','', WinGetHandle("[CLASS:Button]"))
EndFunc

enter image description here

修改

关于 CTRL + ALT + DEL 组合键（或其他窗口组合键），请查看此链接以获取有关如何禁用它们：

http://tamas.io/c-disable-ctrl-alt-del-alt-tab-alt-f4-start-menu-and-so-on/

如果主要锁定，如何在扩展监视器中连续显示Windows窗体

1 个答案: