Question

当评估这个超级简单的core.match表达式时，我得到：

(match [(class "3.14")]
       [Integer] "Integer"
       [Double] "Doubler")
; => "Integer"

这怎么可能是正确的，我错过了关于core.match的基本内容吗？在此表单上执行macroexpand-1可以得到：

=> (clojure.core/let [ocr-2751 (class "3.14")] (clojure.core/let [Integer ocr-2751] "Integer"))

任何指示赞赏。

Answer 1

就像@Arthur所说，通常core.match会将值绑定到符号。但是，显然，first tries to match against locals。谁知道？

无论如何，在匹配之前将这些类绑定为let中的本地人，这样你就可以了：

(let [Integer java.lang.Integer
      String  java.lang.String]
  (match [(class "3.14")]
         [Integer] "Integer"
         [String] "String"))

Answer 2

core.match允许您为匹配子句中的一个值命名，如此（来自examples）

(let [x 1 y 2]
  (match [x y]
    [1 b] b
    [a 2] a
    :else nil))

在此示例中，如果第一个匹配值为1，则在用于生成结果的表达式中，可以使用名称b访问第二个值。

因为match子句中的任何符号都被解释为将相应值绑定到该名称的指令，所以在您的情况下，名称Integer被绑定到值java.lang.String

user> (match [(class "3.14")]
             [Integer] Integer
             [Double] "Doubler")
java.lang.String

user> (match [(class "3.14")]
             [name-to-bind] name-to-bind
             [Double] "Doubler")
java.lang.String

从文档中不清楚是否有办法使用core.match来评估匹配子句而不是绑定它。可以通过匹配字符串来解决这个问题，尽管它会失去一些优雅：

user> (match [(str (class (int 3)))]
             ["class java.lang.Integer"] "Integer"
             ["class java.lang.String"] "String"
             ["class java.lang.Double"] "Double")
"Integer"
user> (match [(str (class "3.14"))]
             ["class java.lang.Integer"] "Integer"
             ["class java.lang.String"] "String"
             ["class java.lang.Double"] "Double")
"String"
user> (match [(str (class 3.14))]
             ["class java.lang.Integer"] "Integer"
             ["class java.lang.String"] "String"
             ["class java.lang.Double"] "Double")
"Double"

Clojure core.match在课堂上不匹配

2 个答案: