Question

我试图通过ANTLR（ANTLRWorks-3.5.2）解析一种语言。目标是输入完整的输入，但Antlr在语法中给出了一个定义部分的解析树，并忽略其余的输入，例如这是我的语法：

grammar asap;
project : '/begin PROJECT' name  module+ '/end PROJECT';    
module : '/begin MODULE'name '/end MODULE'; 
name :   IDENT ;              
IDENT :     ('a'..'z'|'A'..'Z')('a'..'z'|'A'..'Z'|'0'..'9'|'_'|'.'|':'|'-')*;

给定输入：

/begin PROJECT HybridSailboat_2 
/begin MODULE engine

/begin A2ML
/include XCP_common_v1_0.aml
"XCP" struct {      
taggedstruct Common_Parameters ;
};
/end A2ML

/end MODULE
/end PROJECT

关于这个输入我只想要解析树包含项目和模块而不是A2ML部分。是否有可能在antlr中忽略输入的某些部分？我可以在语法中指定不重要部分的起点和终点吗？

Answer 1

只需将A2ML部分与词法分析器中的单个标记匹配，然后skip()：

grammar asap;

project
 : BEGIN_PROJECT name module* END_PROJECT EOF
 ;

module
 : BEGIN_MODULE name END_MODULE
 ;

name
 :   IDENT
 ;  

IDENT
 : ('a'..'z'|'A'..'Z') ('a'..'z'|'A'..'Z'|'0'..'9'|'_'|'.'|':'|'-')*
 ;

BEGIN_PROJECT
 : '/begin' S 'PROJECT'
 ;

END_PROJECT
 : '/end' S 'PROJECT'
 ;

BEGIN_MODULE
 : '/begin' S 'MODULE'
 ;

END_MODULE
 : '/end' S 'MODULE'
 ;

A2ML
 : '/begin' S 'A2ML' .* '/end' S 'A2ML' {skip();}
 ;

SPACES
 : S {skip();}
 ;

fragment S
 : (' ' | '\t' | '\r' | '\n')+
 ;

使用ANTLR解析时忽略输入的某些部分

1 个答案: