表格显示所选答案的百分比（男性，女性）

Question

我的研究中的人已完成问卷调查。其中一个问题涉及参与者阅读场景/ vingette，然后要求他们在场景中“识别问题”。然后向他们提供9个选项（多重回答问题）。

在我的数据文件中，男性和女性用数字编码。我目前正在尝试创建一个表格，其中包含一列中男性9个选项中每个选项的响应百分比（增加到100％），而另一个列中的女性（100％）。

我知道这可能很简单，但我完全忘记了！有关如何在SPSS中实现这一目标的任何帮助？

Answer 1

您可以将MULT RESPONSE GROUPS命令与/BASE=RESPONSES选项一起使用。

*** Create some example fake data.

INPUT PROGRAM.
LOOP #i = 1 TO 15.
  LOOP #g = 1 TO 2.
    COMPUTE Gender = #g.
     DO REPEAT response = r1 TO r9.
       COMPUTE response = TRUNC(RV.UNIFORM(0,2)).
     END REPEAT.
     END CASE.
  END LOOP.
END LOOP.
END FILE.
END INPUT PROGRAM.

FORMATS Gender r1 TO r9 (F1.0).
VALUE LABELS Gender 
 1 'Male'
 2 'Female'.
EXECUTE.

这就是命令与示例数据的相似之处：

MULT RESPONSE GROUPS=$responses (r1 r2 r3 r4 r5 r6 r7 r8 r9 (1)) 
  /VARIABLES=Gender(1 2) 
  /TABLES=$responses BY Gender
  /BASE=RESPONSES
  /CELLS=COLUMN.

Answer 2

听起来您可以从CROSSTABS程序获得所需内容，请参阅下面的示例，并使用我的默认设置生成图像。

*Example fake data.
INPUT PROGRAM.
LOOP #i = 1 TO 15.
  LOOP #g = 1 TO 2.
    COMPUTE Gender = #g.
    COMPUTE Response = TRUNC(RV.UNIFORM(1,10)).
    END CASE.
  END LOOP.
END LOOP.
END FILE.
END INPUT PROGRAM.
FORMATS Gender Response (F1.0).
VALUE LABELS Gender 
 1 'Male'
 2 'Female'.

*Table.
CROSSTABS TABLE Response BY GENDER /CELLS=COL.