Question

我有一个文本文件，如下所示：

value1 value2 value3 value4

我想使用XSLT

将其转换为以下xml

 <values>
    <value>value1</value>
    <value>value2</value>
    <value>value3</value>
     <value>value4</value>
   </values>

提前致谢。

Answer 1

假设XSLT 2.0，

<xsl:template name="main">
 <values>
  <xsl:for-each select="tokenize(unparsed-text('input.txt'), '\s+')">
   <value><xsl:value-of select="."/></value>
  </xsl:for-each>
 </values>
</xsl:template>

Answer 2

如果您可以编辑输入，使其包含根元素，并将制表符作为分隔符，如下所示：

<root>value1    value2  value3  value4</root>

然后，您可以应用以下样式表：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
    <xsl:output indent="yes" omit-xml-declaration="yes"/>

    <xsl:template match="/">
        <values>
            <xsl:call-template name="tokenizeString">
                <xsl:with-param name="list" select="."/>
                <xsl:with-param name="delimiter" select="'&#x9;'"/>
            </xsl:call-template>
        </values>
    </xsl:template>

    <xsl:template name="tokenizeString">
        <!--passed template parameter -->
        <xsl:param name="list"/>
        <xsl:param name="delimiter"/>
        <xsl:choose>
            <xsl:when test="contains($list, $delimiter)">
                <value>
                    <!-- get everything in front of the first delimiter -->
                    <xsl:value-of select="substring-before($list,$delimiter)"/>
                </value>
                <xsl:call-template name="tokenizeString">
                    <!-- store anything left in another variable -->
                    <xsl:with-param name="list" select="substring-after($list,$delimiter)"/>
                    <xsl:with-param name="delimiter" select="$delimiter"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:choose>
                    <xsl:when test="$list = ''">
                        <xsl:text/>
                    </xsl:when>
                    <xsl:otherwise>
                        <value>
                            <xsl:value-of select="$list"/>
                        </value>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

并生产：

<values>
   <value>value1</value>
   <value>value2</value>
   <value>value3</value>
   <value>value4</value>
</values>

使用XSLT将文本转换为xml

2 个答案: