Question

我在Excel 2010中创建了一个文档但是，我希望从中获取的功能似乎不可能（至少不能使用默认的Excel函数）而且我对VB编程知之甚少制作我自己的UDF。（我实际上使用的是我在网上找到的一部分，它可以满足我的需求，但不能满足我的所有需求。）

让我分解一下：

我有多个字段组，其中用户可以添加数字（有些将为空白，有些将包含一个数字，有些将包含多个以逗号分隔的数字）
我有一个“概述”表，我想在几个不同的部分中连接这些数字（并删除任何重复数据）（仅查看特定的字段组）。

我发现一个ConcatIf UDF对此工作得相当好，但它不能处理连续的非连续单元格（例如，我想连接并删除单元格D30，G30，J30和M30中的重复项）（这是UDF：）

Function ConcatIf(ByVal compareRange As Range, ByVal xCriteria As Variant, Optional ByVal stringsRange As Range, _ 
Optional Delimiter As String, Optional NoDuplicates As Boolean) As String 
Dim i As Long, j As Long 
With compareRange.Parent 
    Set compareRange = Application.Intersect(compareRange, Range(.UsedRange, .Range("a1"))) 
End With 
If compareRange Is Nothing Then Exit Function 
If stringsRange Is Nothing Then Set stringsRange = compareRange 
Set stringsRange = compareRange.Offset(stringsRange.Row - compareRange.Row, _ 
stringsRange.Column - compareRange.Column) 

For i = 1 To compareRange.Rows.Count 
    For j = 1 To compareRange.Columns.Count 
        If (Application.CountIf(compareRange.Cells(i, j), xCriteria) = 1) Then 
            If InStr(ConcatIf, Delimiter & CStr(stringsRange.Cells(i, j))) <> 0 Imp Not (NoDuplicates) Then 
                ConcatIf = ConcatIf & Delimiter & CStr(stringsRange.Cells(i, j)) 
            End If 
        End If 
    Next j 
Next i 
ConcatIf = mid(ConcatIf, Len(Delimiter) + 1) 
End Function

它也无法将“一个单元格中的多个数字”作为单独的数字处理。

有没有办法让Concatenate UDF“解析”它正在查看的单元格，以查找多个数字单元格和单个数字单元格之间的重复项，然后输出结果？最好允许它采取一系列非连续的细胞来处理（跨越不同的纸张）。

很抱歉，如果解释有点复杂，那是我第一次请求这种帮助。：X

以下是一个例子：

如果我的单元格包含：

2,4,6-
2,6
2
4
6
6,8

我希望能够简单地得到：

2,4,6,8

现在，相反，我会：

2,4,6,2,6,6,8

Answer 1

尝试以下方法。如果您需要更改分隔符等，您可以适当地调整它。我已经记录了它正在做什么以及为什么。

示例公式：=blah(A1:A7,A8,C9)（也可以从代码中调用）

示例输出：2,4,6,8

Public Function Blah(ParamArray args()) As String
    'Declarations
    Dim uniqueParts As Collection
    Dim area As Range
    Dim arg, arr, ele, part
    Dim i As Long

    'Initialisations
    Set uniqueParts = New Collection

    'Enumerate through the arguments passed to this function
    For Each arg In args
        If TypeOf arg Is Range Then 'range so we need to enumerate its .Areas
            For Each area In arg.Areas
            arr = area.Value 'for large ranges it is greatly quicker to load the data at once rather than enumerating each cell in turn
                For Each ele In arr 'enumerate the array
                     addParts CStr(ele), uniqueParts 'Call our sub to parse the data
                Next ele
            Next area
        ElseIf VarType(arg) > vbArray Then 'an array has been passed in
            For Each ele In arg 'enumerate the array
                addParts CStr(ele), uniqueParts 'Call our sub to parse the data
            Next ele
        Else 'assume can be validly converted to a string. If it cannot then it will fail fast (as intended)
            addParts CStr(arg), uniqueParts 'Call our sub to parse the data
        End If
    Next arg

    'process our results
    If uniqueParts.Count > 0 Then
        ReDim arr(0 To uniqueParts.Count - 1)
        For i = 1 To uniqueParts.Count
            arr(i - 1) = uniqueParts(i)
        Next i
        'we now have an array of the unique parts, which we glue together using the Join function, and then return it
        Blah = Join(arr, ",")
    End If

End Function
'Sub to parse the data. In this case the sub splits the string and adds the split elements to a collection, ignoring duplicates
Private Sub addParts(partsString As String, ByRef outputC As Collection) 
'ByRef is unecessary but I use it to document that outputC must be instantiated
    Dim part
    For Each part In Split(partsString, ",")
        On Error Resume Next 'existing same key will raise an error, so we skip it and just carry on
        outputC.Add part, part
        On Error GoTo 0
    Next part
End Sub

在Excel 2010中，如何在包含多个值单元格的单元格范围内删除重复项并连接值？

1 个答案: