Question

我的程序

CREATE OR REPLACE PROCEDURE my_procedure(res OUT SYS_REFCURSOR , p_LstKH CLOB)
AS
CURSOR c_dsKH
  IS
    SELECT TO_NUMBER(REGEXP_SUBSTR(p_LstKH,'[^,]+', 1, level)) value FROM dual
    CONNECT BY REGEXP_SUBSTR(p_LstKH, '[^,]+', 1, level) IS NOT NULL;
BEGIN
...
END;

我想拆分长字符串p_LstKH然后放入CURSOR c_dsKH。示例：p_LstKH ='1,2，....，10000'

c_dsKH.value
1
2
...
10000

然而，当我执行该程序时，我收到错误“没有足够的内存用于连接操作”。我试图用p_LstKH VARCHAR2替换参数p_LstKH CLOB，然后我得到其他错误“ORA-06502：PL / SQL：数字或值错误：字符串缓冲区太小”。

我现在该怎么办？简单地说，我想拆分一根长串。谢谢大家！

Answer 1

您可以根据逗号进行自己的拆分，并使用流水线函数返回值：

create or replace function split_clob(p_lstkh clob)
return sys.odcivarchar2list pipelined
as
  start_pos pls_integer := 0;
  end_pos pls_integer := 0;
  clob_length pls_integer;
  str varchar2(4000);
begin
  clob_length := dbms_lob.getlength(p_lstkh);
  while end_pos <= clob_length loop
    start_pos := end_pos + 1;
    end_pos := dbms_lob.instr(p_lstkh, ',', start_pos, 1);
    if end_pos <= 0 then
      end_pos := clob_length + 1;
    end if;
    str := dbms_lob.substr(p_lstkh, end_pos - start_pos, start_pos);
    pipe row (str);
  end loop;
end;
/

然后你可以把它作为一个表格来对待：

select * from table(split_clob('X,Y,Z'));

COLUMN_VALUE
------------
X            
Y            
Z

如果您仍然想要作为参考光标，您的过程可以使用该光标选择，而不是连接。

作为一个演示，展示它使用超过32k的实际（虚构）clob：

declare
  clob_val clob := 'A,B,C,D,E,F,G,H,I';
begin
  for i in 1..2000 loop
    dbms_lob.append(clob_val, ',A,B,C,D,E,F,G,H,I');
  end loop;
  dbms_output.put_line('Clob size: ' || dbms_lob.getlength(clob_val));
  for r in (select * from table(split_clob(clob_val)) where rownum < 6) loop
    dbms_output.put_line(r.column_value);
  end loop;
end;
/

anonymous block completed
Clob size: 36017
A
B
C
D
E

Answer 2

这应该可行，但它需要一个返回refcursor的函数。如果你可以使用它：

create or replace
function splitter(pc CLOB) return sys_refcursor
as
  lc sys_refcursor;
begin
  open lc for
    with s(tot, sub, offset) as (
      select pc||',' tot, 
        dbms_lob.substr(pc, dbms_lob.instr(pc, ',', 1)-1, 1) sub, 
        dbms_lob.instr(pc, ',', 1)+1 offset
      from dual
      union all
      select tot, 
        dbms_lob.substr(tot, dbms_lob.instr(tot, ',', offset+1)-offset, offset), 
        dbms_lob.instr(tot, ',', offset+1)+1
      from s
      where offset < dbms_lob.getlength(tot)
    )
    select sub
    from s;

  return lc;
end;
/

var c refcursor;
exec :c := splitter('a,b,c,d,e,f');
print c;

oracle - 使用带有CLOB参数的connect by语句

2 个答案: