Question

    function GetFileIcon(const filename:string): HICON;
var
  shfi: TShFileInfo;
begin
  try
    FillChar(shfi, SizeOf(TShFileInfo), 0);
    ShGetFileInfo(PChar(filename), 0, shfi, SizeOf(TShFileInfo), SHGFI_ICON or SHGFI_LARGEICON);
    Result := shfi.hIcon;
  except
    Result := 0;
  end;
end;

使用delphi xe2，在win 7 64bits上，当在Tthread中调用时，此函数通常会返回0，但在从主线程调用时总是正常工作。它看起来像一个shell初始化问题，因为一段时间后它也可以在Thread中工作。我在堆栈溢出（Calling SHGetFileInfo in thread to avoid UI freeze）中发现了一个类似的问题，但是它适用于c ++语言，所以我没有对其进行排序。

更新：看起来ShGetFileInfo不是线程安全的。当有多个线程同时调用它时，它会失败。见大卫赫弗曼的回答如下。同时使用CoInitializeEx而不是Coinitialize对多线程没有帮助。您必须使用TCriticalSection对访问进行serilize。

Answer 1

来自documentation：

在调用SHGetFileInfo之前，必须使用CoInitialize或OleInitialize初始化组件对象模型（COM）。

在GUI应用程序中，COM在主线程中初始化。但是从其他线程不会自动发生。您需要明确地这样做。

除此之外，您没有正确处理错误。请记住，Windows API函数不会引发异常。所以你的异常处理程序是没有意义的，应该被删除。相反，您需要检查调用SHGetFileInfo的返回值，如文档中所述。

除此之外，您的代码可以运行，正如此程序所示：

{$APPTYPE CONSOLE}

uses
  Classes, Windows, ActiveX, ShellAPI;

var
  hThread: THandle;
  ThreadId: Cardinal;

function ThreadFunc(Parameter: Pointer): Integer;
var
  shfi: TSHFileInfo;
begin
  CoInitialize(nil);
  Try
    if ShGetFileInfo('C:\windows\explorer.exe', 0, shfi, SizeOf(shfi), SHGFI_ICON or SHGFI_LARGEICON)=0 then
    begin
      Writeln('ShGetFileInfo Failed');
      Result := 1;
      exit;
    end;
    Writeln(shfi.hIcon);
  Finally
    CoUninitialize;
  End;
  Result := 0;
end;

begin
  hThread := BeginThread(nil, 0, ThreadFunc, nil, 0, ThreadId);
  WaitForSingleObject(hThread, INFINITE);
  CloseHandle(hThread);
  Readln;
end.

我希望您观察到的任何失败实际上与您要检查的特定文件有关。

更新：似乎ShGetFileInfo不是线程安全的。当有多个线程同时调用它时，它会失败。我相信您需要使用锁定序列化ShGetFileInfo的调用。例如，TCriticalSection。

以下程序基于您在评论中提供的SSCCE，演示了这一点：

{$APPTYPE CONSOLE}

uses
  SysUtils,
  Classes,
  SyncObjs,
  Windows,
  ActiveX,
  ShellAPI;

var
  hThreads: TWOHandleArray;
  ThreadId: Cardinal;
  Lock: TCriticalSection;

function ThreadFunc(Parameter: Pointer): Integer;
var
  shfi: TSHFileInfo;
  randomnumber: integer;
  fname: string;
begin
  CoInitialize(nil);
  Try
    fname := 'c:\desktop\file'+IntToStr(Integer(Parameter))+'.exe';

    Lock.Acquire;
    try
      if ShGetFileInfo(pchar(fname), 0, shfi, SizeOf(shfi), SHGFI_ICON or SHGFI_LARGEICON)=0 then
      begin
        Writeln('ShGetFileInfo Failed');
        Result := 1;
        exit;
      end;
      Writeln(shfi.hIcon);
    finally
      Lock.Release;
    end;
  Finally
    CoUninitialize;
  End;
  Result := 0;
end;

var
i: integer;
begin
  Lock := TCriticalSection.Create;
  for i := 0 to 9 do
    hThreads[i] := BeginThread(nil, 0, ThreadFunc, Pointer(i), 0, ThreadId);

  WaitForMultipleObjects(10, @hThreads,true, INFINITE);

  Readln;
end.

删除关键部分，对ShGetFileInfo的调用成功，但返回0图标句柄。使用临界区，将返回有效的图标句柄。

Delphi从线程调用shgetfileinfo失败

1 个答案: