Question

我创建了以下Pig脚本来过滤来自提及电影标题的Web文档（Common Crawl）集合中的句子（来自预定义的电影标题数据文件），对这些句子应用情感分析并将这些情绪分组电影。

register ../commoncrawl-examples/lib/*.jar; 
set mapred.task.timeout= 1000;
register ../commoncrawl-examples/dist/lib/commoncrawl-examples-1.0.1-HM.jar;
register ../dist/lib/movierankings-1.jar
register ../lib/piggybank.jar;
register ../lib/stanford-corenlp-full-2014-01-04/stanford-corenlp-3.3.1.jar;
register ../lib/stanford-corenlp-full-2014-01-04/stanford-corenlp-3.3.1-models.jar;
register ../lib/stanford-corenlp-full-2014-01-04/ejml-0.23.jar;
register ../lib/stanford-corenlp-full-2014-01-04/joda-time.jar;
register ../lib/stanford-corenlp-full-2014-01-04/jollyday.jar;
register ../lib/stanford-corenlp-full-2014-01-04/xom.jar;

DEFINE IsNotWord com.moviereviewsentimentrankings.IsNotWord;
DEFINE IsMovieDocument com.moviereviewsentimentrankings.IsMovieDocument;
DEFINE ToSentenceMoviePairs com.moviereviewsentimentrankings.ToSentenceMoviePairs;
DEFINE ToSentiment com.moviereviewsentimentrankings.ToSentiment;
DEFINE MoviesInDocument com.moviereviewsentimentrankings.MoviesInDocument;

DEFINE SequenceFileLoader org.apache.pig.piggybank.storage.SequenceFileLoader();

-- LOAD pages, movies and words
pages = LOAD '../data/textData-*' USING SequenceFileLoader as (url:chararray, content:chararray);
movies_fltr_grp = LOAD '../data/movie_fltr_grp_2/part-*' as (group: chararray,movies_fltr: {(movie: chararray)});

-- FILTER pages containing movie
movie_pages = FILTER pages BY IsMovieDocument(content, movies_fltr_grp.movies_fltr);

-- SPLIT pages containing movie in sentences and create movie-sentence pairs
movie_sentences = FOREACH movie_pages GENERATE flatten(ToSentenceMoviePairs(content, movies_fltr_grp.movies_fltr)) as (content:chararray, movie:chararray);

-- Calculate sentiment for each movie-sentence pair
movie_sentiment = FOREACH movie_sentences GENERATE flatten(ToSentiment(movie, content)) as (movie:chararray, sentiment:int);

-- GROUP movie-sentiment pairs by movie
movie_sentiment_grp_tups = GROUP movie_sentiment BY movie;

-- Reformat and print movie-sentiment pairs
movie_sentiment_grp = FOREACH movie_sentiment_grp_tups GENERATE group, movie_sentiment.sentiment AS sentiments:{(sentiment: int)};
describe movie_sentiment_grp;

在网络抓取的一小部分上进行的测试运行显示成功地给了我一对带有整数数据集的电影标题（从1到5，表示非常消极，负面，中立，正面和非常正面）。作为最后一步，我想将这些数据转换为成对电影标题和包含元组的数据集，其中包含为此电影标题及其计数存在的所有不同整数。脚本末尾描述的movie_sentiment_grp返回：

movie_sentiment_grp: {group: chararray,sentiments: {(sentiment: int)}}

所以基本上我可能需要对movie_sentiment_grp的每个元素进行FOREACH并将情感数据库分组为相同值的组，然后使用COUNT（）函数来获取每个组中元素的数量。然而，我无法找到关于如何将整数数据集分组为相同值的组的任何内容。有谁知道怎么做？

虚拟解决方案：

movie_sentiment_grp_cnt = FOREACH movie_sentiment_grp{
    sentiments_grp = GROUP sentiments BY ?;
}

Answer 1

从CountEach查看Apache DataFu UDF。如果有一个包，它将生成一个新的独特元组包，每个相应的元组附加计数。

文档中的示例应该明确说明：

DEFINE CountEachFlatten datafu.pig.bags.CountEach('flatten');

-- input: 
-- ({(A),(A),(C),(B)})
input = LOAD 'input' AS (B: bag {T: tuple(alpha:CHARARRAY, numeric:INT)});

-- output_flatten: 
-- ({(A,2),(C,1),(B,1)})
output_flatten = FOREACH input GENERATE CountEachFlatten(B);

对于你的情况：

DEFINE CountEachFlatten datafu.pig.bags.CountEach('flatten');

movie_sentiment_grp_cnt = FOREACH movie_sentiment_grp GENERATE
     group,
     CountEach(sentiments);

Answer 2

你走在正确的轨道上。 movie_sentiment_grp格式正确，嵌套FOREACH是正确的，但您不能在其中使用GROUP。解决方案是使用UDF。像这样：

<强> myudfs.py

#!/usr/bin/python

@outputSchema('sentiments: {(sentiment:int, count:int)}')
def count_sentiments(BAG):
    res = {}
    for s in BAG:
        if s in res:
            res[s] += 1
        else:
            res[s] = 1
    return res.items()

此UDF的使用方式如下：

Register 'myudfs.py' using jython as myfuncs;

movie_sentiment_grp_cnt = FOREACH movie_sentiment_grp 
                          GENERATE group, myfuncs.count_sentiments(sentiments) ;

在猪中用相同的值对数据库进行分组

2 个答案: